17の新機能: ［発行］コマンドでは、発行先のスペースまたはフォルダを指定する必要があります。
JSLを使って、JMPのレポートやデータテーブルをJMP Liveに投稿することができます。投稿は、特定のスペースか、スペース内のフォルダに対して発行されます。そのスペースへのアクセス権をもつ個人やグループのみが、投稿を参照できます。
スペースキーを使って、個人用スペースやその他のスペースに発行し、投稿の共有範囲をコントロールできます。JMP Liveのスペースキーを確認するには、そのスペースに移動して、詳細アイコンをクリックします。
• 自分専用のスペースに発行するには、ショートカットとして波形符号（~）を入力します。個人用スペースは、先頭に必ず波形符号が付きます。
• 別のスペースに発行するには、スペースキーを指定します。
ヒント: JMP Liveの全ユーザに投稿を共有するには、ALLUSERSスペースキーを指定します。投稿は、All Usersスペースに表示されるようになります。
この例では、グラフビルダーのレポートを自分専用のスペースに発行します。
Names Default To Here( 1 );
// Big Classデータテーブルを開く。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
// グラフビルダーのテーブルスクリプトを実行し、レポートへの参照をgbsmootherに格納する。
gbsmoother = dt << Run Script( "グラフビルダー 平滑線" );
// JMP Liveサーバーに接続する。
liveconnection = New JMP Live();
// gbsmootherレポートをcontentに追加する。
content = New JMP Live Content( gbsmoother );
/* contentを自分専用のスペースに発行する。確立したJMP Live接続を使い、jmpliveresultというJMP Liveオブジェクトを戻す。*/
jmpliveresult = liveconnection << Publish( content, Space( "~" ) );
// すべてのデータテーブルを保存せずに閉じる。
Close All( Data Tables, NoSave );
17の新機能: Create Folderコマンドで、タイトルと説明に加え、発行先のスペースも指定するようになりました。既存のフォルダ内にフォルダを発行することもできます。
作成したフォルダを参照できるのは、フォルダがあるスペースにアクセスできるユーザのみとなります。
この例では、自分専用のスペースにフォルダを作成します。
Names Default To Here( 1 );
// JMP Liveサーバーに接続する。
liveconnection = New JMP Live();
/* 自分専用のスペースにフォルダを作成し、タイトルと説明を指定する。確立したJMP Live接続を使い、jmpliveresultというJMP Liveオブジェクトを戻す。*/
jmpliveresult = liveconnection << Create Folder( Space( "~" ), Title( "フォルダ作成の例" ), Description( "スクリプトの索引にあるフォルダ作成の例") );
// 結果をスクリプト可能にする。
folder = jmpliveresult << As Scriptable;
// フォルダIDを取得する。
id = folder << Get ID();
// フォルダIDをJMPのログに出力する。
Write( "ID: ", id );
スペースにある既存のフォルダに発行するには、フォルダIDが必要です。JMP LiveでフォルダIDを確認するには、フォルダをクリックします。すると、IDがURL内に表示されます。詳細アイコンをクリックして、投稿IDをコピーすることもできます。
この例では、グラフビルダーのレポートを、自分専用のスペースにあるフォルダに発行します。
Names Default To Here( 1 );
// Big Classデータテーブルを開く。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
// グラフビルダーのテーブルスクリプトを実行し、レポートへの参照をgbsmootherに格納する。
gbsmoother = dt << Run Script( "グラフビルダー 平滑線" );
// JMP Liveサーバーに接続する。
liveconnection = New JMP Live();
/* 自分専用のスペースにフォルダを作成し、タイトルを指定する。確立したJMP Live接続を使い、jmpliveresultというJMP Liveオブジェクトを戻す。*/
jmpliveresult = liveconnection << Create Folder( Space( "~" ), Title( "フォルダへの発行の例" ) );
// 結果をスクリプト可能にする。
folder = jmpliveresult << As Scriptable;
// gbsmootherレポートをcontentに追加する。
content = New JMP Live Content( gbsmoother );
/* contentを自分専用のスペースに発行する。確立したJMP Live接続を使い、jmpliveresultというJMP Liveオブジェクトを戻す。*/
jmpliveresult = liveconnection << Publish( content, Folder( ID( folder << Get ID ) ) );
// すべてのデータテーブルを保存せずに閉じる。
Close All( Data Tables, NoSave );
17の新機能: これまでのバージョンでは、複数のレポートを発行すると、新しいフォルダが自動的に作成されていましたが、バージョン17では、Create Folderコマンドを追加する必要があります。Create Folderコマンドには、これまでPublishコマンドで指定していたタイトルと説明を指定してください。さらに、Publishコマンドを編集してタイトルと説明を削除し、直前の手順で作成したフォルダに対して発行します。
JSLでは、複数のレポートを既存のフォルダに発行するか、または、新しくフォルダを作成してそこに発行することができます。
この例では、グラフビルダーの2つのレポートを、自分専用のスペースにあるフォルダに発行します。
Names Default To Here( 1 );
// Big Classデータテーブルを開く。
bc = Open( "$SAMPLE_DATA/Big Class.jmp" );
/* グラフビルダーの2つのテーブルスクリプトを実行し、レポートへの参照をgbsmoother、gblineに格納する。 */
gbsmoother = bc << Run Script( "グラフビルダー 平滑線" );
gbline = bc << Run Script( "グラフビルダー 折れ線・棒" );
// JMP Liveサーバーに接続する。
liveconnection = New JMP Live();
/* 自分専用のスペースにフォルダを作成し、タイトルを指定する。確立したJMP Live接続を使い、jmpliveresultというJMP Liveオブジェクトを戻す。*/
jmpliveresult = liveconnection << Create Folder( Space( "~" ), Title( "複数のレポートの例" ) );
// 結果をスクリプト可能にする。
folder = jmpliveresult << As Scriptable;
// gbsmootherレポートをcontent1に追加する。
content1 = New JMP Live Content( gbsmoother );
// gblineレポートをcontent2に追加する。
content2 = New JMP Live Content( gbline );
// 新しく作成したフォルダに、content1とcontent2を（リスト形式で）発行する。
jmpliveresult = liveconnection << Publish( {content1, content2}, Folder( ID( folder << Get ID ) ) );
// JMPのすべてのデータテーブルを保存せずに閉じる。
Close All( Data Tables, NoSave );