JMP Liveレポートの元となるデータに変更が生じた場合は、データのみを更新すれば、JMP Liveでそのデータを使用するレポートも、自動的に再生成されます。
次の例では、「一変量の分布」レポートを作成し、そのレポートおよび元データを自分専用のスペースにあるフォルダに発行してから、データを更新します。
この例では、「一変量の分布」レポートを自分専用のスペースにあるフォルダに発行してから、JMP Liveの既存のデータを更新します。
Names Default To Here( 1 );
// Big Classサンプルデータテーブルを開く。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
// 「一変量の分布」テーブルスクリプトを実行し、レポートへの参照をdistに格納する。
dist = dt << Run Script( "一変量の分布" );
// JMP Liveサーバーに接続する。
liveconnection = New JMP Live();
/* 自分専用のスペースにフォルダを作成し、タイトルを指定する。確立したJMP Live接続を使い、jmpliveresultというJMP Liveオブジェクトを戻す。*/
jmpliveresult = liveconnection << Create Folder( Space( "~" ), Title( "データ更新の例" ) );
// 結果をスクリプト可能にする。
folder = jmpliveresult << As Scriptable;
// distレポートをcontentに追加する。
content = New JMP Live Content( dist );
// 新しく作成したフォルダにcontentを発行し、フォルダIDを取得する。
jmpliveresult = liveconnection << Publish( content, Folder( ID( folder << Get ID ) ) );
// 作成した投稿のリストをスクリプト可能にする。
postlist = jmpliveresult << As Scriptable;
// 投稿の詳細を取得する。
dataId = "";
For( i = 1, i <= postlist << Get Number Of Items, i += 1,
type = postlist[i] << Get Type();
If( type == "Data",
dataId = postlist[i] << Get ID
);
);
// Update DataコマンドとdataIdを使って、JMP Liveのデータテーブルを更新する。
liveresult = liveconnection << Update Data( dataId, dt );