该帮助的版本不再更新，请参见https://www.jmp.com/support/help/zh-cn/15.2 获取最新的版本.


JSL Syntax Reference • JSL Messages • Data Tables
上一个
 • 
下一个
Data Tables
dt<<Add Column Properties(property argument, ...)
Adds the specified properties to the selected column.
dt<<Add Multiple Columns("column prefix", n, <before first|after last|after(column)>, Character|Numeric|Row State, <field width(n)>)
Adds n columns to dt at the position indicated.
dt<<Add Rows(<n>, <at start|at end|after(m)>|{list of (column name=value) pairs})
Description
Adds rows at the start, at the end, or after a specified row in the data table. The message can also add rows based on the specified column name and value pairs. Those rows are added to the end of the data table.
Examples
The following example specifies the start and end of the new rows:
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Add Rows( 3, after( 5 ) );
The following example specifies the column name and value pairs. The new row is added to the end of the data table.
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Add Rows( {name = "David", age = 15} );
dt<<Add Scripts to Table(script, ...)
dt<<Add Properties to Table(script, ...)
Adds the specified scripts to the data table.
dt<<Anonymize(<columns(name(s))>, <Output Table Name(string)>);
Removes unique identifiers from data, some column properties, and table scripts. Applies to a data table or selected columns.
dt<<Begin Data Update
Holds off display updating to allow for quick updating of data table cells. Use End Data Update in conjunction with this command to turn display updating back on.
Notes
Begin Data Update does not affect the data refresh due to some other table manipulations. For example, when you delete or add columns, the data table is updated and then the data update begins.
dt<<Clear Column Selection
Deselects all selected columns.
dt<<Clear Edit Lock(<"modify cells">, <"add rows">, <"add columns">, <"delete rows">, <"delete columns">)
Allows the specified data table operation again.
dt<<Clear Row States
Cancels any row states in effect.
dt<<Clear Select
Turns off the current selection.
dt<<Clone Formula Column(column, n, Substitute Column Reference(column1, {list}))
Creates n new formula columns, substituting references to column1 with columns from the list into the formula from the original column.
dt<<Close Data Grid(Boolean)
Closes the data table grid.
dt<<Close Side Panels(Boolean)
Closes the side panel in a data table.
dt<<Color or Mark by Column(col, <optional arguments>)
dt<<Color by Column(col, <optional arguments>)
Function
Assigns colors or markers according to the values of a data table column. If no optional arguments are provided, row states are used.
Arguments
Color Number(n)
Uses the specified quoted JMP color.
Color Theme("theme")
Uses the specified quoted color theme.
Marker Theme("named argument")
Uses the specified quoted marker theme: "standard", "hollow", "paired", "classic", or "alphanumeric".
Continuous Scale
For Color by Column, assigns colors in a chromatic sequential fashion based on the values in the highlighted column.
Reverse Scale
Reverses the color scheme in use.
Excluded Rows
Applies the row states to excluded columns.
Make Window with Legend
Creates a separate window with a legend.
dt<<Color Rows by Row State
Colors the rows in the data table grid using the color assignments by row states. Send the message again to turn off the row colors.
dt<<Combine Columns
Combines several columns into a single column. Each source columns’ values are separated by the specified delimiter.
Examples
dt = Open( "$SAMPLE_DATA/Consumer Preferences.jmp" );
dt << Combine Columns(
Delimiter( "," ),
Columns(
:Brush After Waking Up,
:Brush After Meal,
:Brush Before Sleep,
:Brush Another Time
),
Column Name( "When to Brush" )
);
dt<<Compress File When Saved(Boolean)
Compresses the file when the data table is saved.
dt<<Compress Selected Columns({column1, ...})
Compresses the listed columns into the most compact form that is possible. Columns with character data are compressed to 1 byte if there are fewer than 255 levels. Columns with numeric data are compressed to 1 byte if the numeric values are between -127 and 127.
dt<<Concatenate(dt2, ..., Keep Formulas, Output Table Name("name"))
Description
Creates a new table ("name") from the rows of dt and dt2.
Returns
A reference to the concatenated data table.
dt<<Copy Multi Columns Properties
Copies all of the column properties for the selected columns into a list of separate lists of properties. Optionally, you can specify a list of source columns instead of preselecting them in the data table.
Example
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
dt << Select Columns( :MODULUS, :ELONG );
dt << Copy Multi Columns Properties;
New Window( "Script", Script Box( "//Try paste here" ) );
or
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
dt << Copy Multi Columns Properties( {:MODULUS, :ELONG} );
New Window( "Script", Script Box( "//Try paste here" ) );
dt<<Copy Selected Properties
Copies the selected table properties to the clipboard.
Example
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Select Properties( {"Distribution", "Oneway"} );
proplist = dt << Copy Selected Properties();
New Window( "Script", Script Box( "//Try pasting here" ) );
dt<<Copy Table Script( "No data" )
Copies the script to recreate the data table onto the clipboard so that it can be pasted somewhere else. Includes the table scripts. Add the "no data" keyword to omit the data.
dt<<Copy Table Scripts
dt<<Copy Selected Properties
Description
Copies the selected scripts to the clipboard.
Example
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Select Properties( {"Distribution", "Oneway"} );
proplist = dt << Copy Table Scripts();
New Window( "Script", Script Box( "//Try pasting here" ) );
dt<<Data Filter(<Mode(...)>, <Add Filter (...)>)
Constructs a data filter. If no arguments are specified, the Add Filter Columns window appears.
Arguments for Mode() include Select(), Show(), and Include(). They are all Boolean. Select defaults to true(1), and Show and Include default to false (0).
Arguments for Add Filter() include Columns(), and Where(). Columns() takes one or more column names separated by commas. You can add one or more WHERE clauses to define the filter.
No Outline Box(Boolean) omits or adds an outline and red triangle menu at the top of the filter window.
or more information, see “Add a Data Filter” in the Scripting Guide and “数据过滤器” in the Using JMP book
dt<<Get Header Height
Returns the column header’s display height (in pixels).
dt<<Data View(<"options">)
Description
Duplicates the data table in a new window. If you specify one of the following quoted arguments, the new data table includes only the corresponding rows.
Returns
A reference to the data view.
Optional Arguments
excluded
Quoted. The new data table includes only the rows that are marked as excluded in the original data table.
labeled | labelled
Quoted. The new data table includes only the rows that are marked as labeled in the original data table.
hidden
Quoted. The new data table includes only the rows that are marked as hidden in the original data table.
selected
Quoted. The new data table includes only the rows that are selected in the original data table.
dt<<Delete Columns(col, col2, ...)
dt<<Delete Column
Deletes column(s) from the data table dt. Specify which column or columns to delete. Without an argument, deletes the selected columns, if any. Delete Column is a synonym.
dt<<Delete Rows(<n>)
dt<<Delete Rows({n, o, p, ...})
dt<<Delete Rows({n::q})
Deletes the currently selected rows or rows specified. Returns the number of rows that were deleted.
dt<<Delete Scripts("name"|{script1, script2, ...})
Deletes the specified script or scripts.
Note
In JMP versions prior to 14, use Delete Property to delete a script.
dt<<Delete Table Property("name"|{property1, property2, ...})
Deletes a table property (for example, a script or variable).
dt<<Delete Table Variable("name")
Deletes a table variable.
dt<<Disable Undo(Boolean)
Disables undo operations in the data table.
dt<<End Data Update
Resumes display updating after a Begin Data Update message. These commands are used for quick updates of the data table when many changes have to be made. Speed is gained by turning off display updating.
dt<<Exclude
dt<<Unexclude
Toggles selected rows in dt from excluded to unexcluded or vice versa.
dt<<Get All Columns As Matrix
Returns the values from all columns of dt in a matrix. Character columns are numbered according to the levels, starting at 1.
dt<<Get As Matrix(<list of columns by name>, <list of columns by number>, <column range>)
Returns values from the numeric columns of dt in a matrix. The default output is all numeric columns.
Examples
dt1 = Open( "$SAMPLE_DATA/Big Class.jmp" );
colnames = dt1 << Get As Matrix(); // returns all numeric columns
Show( colnames );
colnames =
[ 12 59 95,
12 61 123,
12 55 74,...]
colnums = dt1 << Get As Matrix( {4, 5} ); // returns columns four and five
Show( colnums );
colnums = [ 59 95, 61 123, 55 74, 66 145, 52 64, 60 84, 61 128, ...]
 
dt2 = Open( "$SAMPLE_DATA/Probe.jmp" );
colrange = dt2 << Get As Matrix( 10::22); // returns columns 10 through 22
Show( colrange );
colrange =
[ -0.08818069845438 0.711340010166168 1.85904002189636 0.396923005580902 4.50656986236572 7.86504983901978 1.53891003131866 -2.76178002357483 0.0711032971739769 5.75577020645142 -3.62023997306824 -0.971698999404907 -0.0525696985423565, ...]
dt<<Get As Report
Returns the data table as a report. If rows and columns are selected in the data table, only those rows and columns are in the report.
Example
The following script returns Big Class.jmp as a report and displays it and a distribution in one window.
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dtRpt = dt << Get As Report;
distRpt = V List Box(
dt << Distribution(
Continuous Distribution( Column( :weight ) ),
Nominal Distribution( Column( :age ) )
)
);
New Window( "Example", H List Box( dtRpt, distRpt ) );
dt<<Get Cell Height
Returns the column header’s cell height.
dt<<Get Column Names("arguments")
Returns a list of column names in a data table. The "arguments" restrict the names retrieved as follows:
"Numeric", "Ordinal", "Rowstate", "Continuous", "Ordinal", and "Nominal" get only the specified types of columns. More than one can be specified. "String" returns a list of strings rather than a list of column references.
dt<<Get Column Reference(list or matrix of col names)
Returns the column reference of the strings in the list or matrix. If no list or matrix is used, JMP returns all column names.
dt<<Get Display Width
Returns the column display width in pixels.
dt<<Get Edit Lock
Returns the disallowed operations on the data table (if cells cannot be edited; rows cannot be added or deleted; and columns cannot be added or deleted).
dt<<Get Excluded Columns
Returns the currently excluded columns in the data table.
dt<<Get Excluded Rows
Returns the rows that are excluded in the data table.
dt<<Get Hidden Columns
Returns the columns that are hidden in the data table.
dt<<Get Hidden Rows
Returns the currently hidden rows in the data table.
dt<<Get Journal
Returns a string that contains journal source for the display box.
Example
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = dt << Bivariate( Y( :weight ), X( :height ) );
rbiv = biv << Report;
Print( rbiv << Get Journal );
dt<<Get Label Columns
dt<<Get Labeled Columns
dt<<Get Labelled Columns
Returns the currently labeled columns in the data table.
Example
In PopAgeGroup.jmp, the Country and Year columns are labeled. The following script returns a list of the labeled column names.
dt = Open( "$SAMPLE_DATA/PopAgeGroup.jmp" );
dt << Get Labeled Columns;
{:Country, :Year}
dt<<Get Labeled Rows
dt<<Get Labelled Rows
Returns the currently labeled rows in the data table.
dt<<Get Name
Returns the name of the table.
dt<<Get Path
Returns the absolute path for the JMP data table. Note that this function is not for imported data that is not saved yet.
dt<<Get Property("name")
Returns the script in the property name.
dt<<Get Row Change Function
Returns the expression that is evaluated when a row is selected.
dt<<Get Row ID Width
Returns the row ID display width in pixels.
dt<<Get Row States
Returns a vector containing the row state for every row in the data table or data filter.
dt<<Get Rows Where(WHERE clause)
Returns the rows in the data table that match the specified where criteria. Some examples are as follows:
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Get Rows Where( :sex == "M" );
dt << Get Rows Where( :sex == "M" & :age < 15 );
dt<<Get Script(<"script name">)
Returns the specified script. If the script name is omitted, Get Script returns a text representation of the data table and all scripts in the table.
dt<<Get Script Group("name")
Returns the list of table scripts in the group. See “Get Groups and Group Names” in the Scripting Guide for examples.
dt<<Get Script Group Names
Returns the list of names of table script groups. See “Get Groups and Group Names” in the Scripting Guide for examples.
dt<<Get Scroll Locked Columns
Returns a list of columns that are locked from scrolling.
dt<<Get Selected(<"column reference">)
Returns a list of selected items. Include the optional "column reference" to return column references instead, such as when you are adding a column to a col list box.
dt<<Get Selected Columns(<"string">)
Returns a list of selected columns as column references. Include the "string" argument to return the selected columns in a string.
Examples
dt << Get Selected Columns();
{:age, :sex, :height}
dt << Get Selected Columns( "string" );
{"age", "sex", "height"}
dt<<Get Selected Properties(<{list of properties}>)
Description
Returns the selected table properties in a list.
Optional Argument
list of properties
specifies the properties to get.
Example
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Select Properties( {2, 4} );
proplist = dt << Get Selected Properties();
// returns the second and fourth table scripts and highlights them
// in the data table
dt<<Get Selected Rows()
Returns the selected rows.
dt<<Get Table Script Names()
Returns a list of the names of all the scripts and properties in the data table.
dt<<Get Table Variable("name")
Returns the value from the variable or script name.
dt<<Get Table Variable Names()
Returns a list of the names of all the variables in the data table.
dt<<Go To Row(n)
Locates and selects row number n in dt.
dt<<Group Columns({col1, col1, ...})
dt<<Group Columns("group name", col, n)
Groups the columns under the specified group name. You can provide either a list of columns to group, or a column name and the number of columns to group. In the latter case, the number n specifies to group the column given with the n-1 columns that follow.
dt<<Group Scripts({script1, script2, ...})
Groups a list of tables scripts in the data table. See “Work with Groups of Table Scripts” in the Scripting Guide for examples.
dt<<Hide
dt<<Unhide
Toggles selected rows in dt from hidden to unhidden or vice versa.
dt<<Hide and Exclude
Hides the selected rows from graphs and excludes them from contributing to calculations.
dt<<Invert Column Selection( <list of columns> )
Selects any column that is currently deselected and deselects any column that is currently selected. If the list of columns is specified, the columns that are not in the list are selected. See “Invert Column Selections” in the Scripting Guide for examples.
dt<<Invert Row Selection
Selects any row that is currently deselected and deselects any row currently selected.
dt<<Is Dirty
Returns 1 if the table has been modified from its saved state. Otherwise, returns 0.
dt<<JMP Query Builder
Enables you to build a query that contains one or more data tables.
dt<<Join(With(dataTable), <Private>, <Invisible>, Select(columns), Select With(columns), (By Matching Columns(col1=col2, ...)|Cartesian|By Row Number), <Merge Same Name Columns>, <Match Flag>, <Copy Formula(Boolean)>, <Suppress Formula Evaluation(Boolean)>, Update, <Drop Multiples(Boolean, Boolean)>, <Include Non Matches(Boolean, Boolean)>, <Preserve Main Table Order>, <Output Table Name("name"))>
Description
Combines data tables dt and table side to side. For details about joining tables, see “连接数据表” in the Using JMP book.
Returns
A data table.
Arguments
Private
Optional. Does not open the resulting data table.
Invisible
Optional. Opens the data table but hides it. The table is displayed in the JMP Home Window’s Window List or the Window > Unhide list.
With(dataTable)
The secondary data table.
Select(columns)
Selects the columns from the main table to be added to the output table. Optional.
Select With(columns)
Selects the columns from the secondary table to be added to the output table.
By Matching Columns(col1=col2, ...)|Cartesian|By Row Number
Determines the method for joining the tables. By Matching Columns(col1=col2, ...) matches values in col1 with col2. If they match, those values will be joined. Cartesian joins two tables using a Cartesian method, where it forms a new table consisting of all possible combinations of the rows from two original tables. JMP crosses the data in the first table with the data in the second to display all combinations of the values in each set. By Row Number joins the two tables side by side. By Matching Columns is the default value.
Merge Same Name Columns
Optional. Merges columns with the same name. Off by default.
Match Flag
Optional. Off by default. Omits the Match Flag column from the joined data table when you are matching by column.
Copy Formula(Boolean for main table, Boolean for secondary table)
Optional. Copies the formulas from the table that you are joining. On by default.
Suppress Formula Evaluation()
Optional. Prevents JMP from evaluating columns’ formulas during the creation of the new table. On by default. Use Suppress Main Table Formula Evaluation to suppress evaluation only in the main table. Use Suppress Second Table Formula Evaluation to suppress evaluation only in the secondary table.
Update
Optional. Replace the data in the main table with the corresponding data from the secondary table. Update is an alias for Update First Table with Data from Second Table.
Drop Multiples(Boolean for main table, Boolean for secondary table)
Optional. Only the first match found is written to the new data table. If you do not enable Drop Multiples in either table, a Cartesian join is performed within each group of matching column values. Off by default.
Include Non Matches(Boolean for main table, Boolean for secondary table)
Optional. Includes non-matching columns. Off by default.
Preserve Main Table Order
Optional. Maintains the order of the original data table in the joined table, instead of sorting by the matching columns. On by default.
Output Table Name("name"))
Optional. The name of the resulting table.
dt<<Journal
Makes a journal from the data table. Only the data grid is included, not notes, variables, or scripts.
Notes
Journals that are created in JMP 14 or later might contain compressed matrix data for large matrices. If you have JSL scripts that open journals and extract data from them, you might need to use the Get Journal message (which does not compress the matrices) rather than saving the journal to disk with the Journal message. See dt<<Get Journal for an example.
dt<<Journal Link(Save(<filepath>)|Embed(), <Button Name(string)>))
Adds a link to the data table in the current journal. If a journal does not exist, a new one is created.
Arguments
filepath
Optional argument. The complete path and filename where the table should be saved. If omitted, the data table should already have a disk location (previously saved or loaded), otherwise the journal link is incomplete and will not reload the table.
Embed
Optional argument. Embeds a JSL script to recreate the data table.
Button Name
Optional argument. The name that is displayed on the button. If the button name is not specified, the button is named after the data table.
dt<<Label
dt<<Unlabel
Toggles selected rows in dt from labeled to unlabeled or vice versa.
dt<<Last Modified
Returns the date on which the data table was last saved.
dt<<Layout
Layout is deprecated and will be removed in a future release. Use Journal instead.
dt<<Lock Data Table
Locks the data table so that data and column properties cannot be added or changed. See dt <<Set Edit Lock(<"modify cells">, <"add rows">, <"add columns">, <"delete rows">, <"delete columns">) for details about locking specific components of a data table.
dt<<Make Indicator Columns( <Append Column Name(Boolean)>, <Include Missing(Boolean)>);
Creates indicator columns of 0 and 1 values for the specified categorical column.
Example
The following example creates indicator columns for the sex column. Append Column Name creates columns named sex_F and sex_M. Otherwise, the columns are named after each level (F and M). Include Missing includes missing values.
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Make Indicator Columns(
Columns( :sex ),
Append Column Name( 1 ),
Include Missing( 1 )
);
dt<<Make RowState Handler
Creates a row state handler function. The argument of the function holds the rows whose row states get changed.
dt<<Make SAS Data Step
Returns the data table as a SAS Data Step.
dt<<Make SAS Data Step Window
Returns the data table as a SAS Data Step and places it in a SAS script window.
dt<<Marker by Column(col)
Assigns markers according to the values of a data table column.
dt<<Markers(n)
Assigns marker n to the selected rows.
dt<<Maximize Display
Deprecated. Use Optimize Display instead.
Forces the data table to remeasure all of its columns and zoom to the best-sized window.
dt<<Move Script Group(group name, to first|to last|after(script)|after(group))
Rearranges the table script groups. See “Move a Script Group” in the Scripting Guide for examples.
dt<<Move Selected Column("name(s)", to first|to last|after("name"))
dt<<Move Selected Columns("name(s)", to first|to last|after("name"))
Moves the selected column or columns in the data table to the specified position. See “Rearrange and Move Columns” in the Scripting Guide for examples.
dt<<Move Rows(At Start|At End|After(n))
Moves the selected rows in the data table to the specified position.
dt<<New Column("name", <“data type”>, <"modeling type">, Format("format", width), <Formula()>, <Set Values>, <properties>)
Description
Adds a new column named "name" after the last column in dt. Unless otherwise specified, columns are numeric, continuous, and 12 characters wide.
Returns
A column reference.
Arguments
name
A quoted string that contains the name of the new column.
data type
An optional argument that defines the data type (Numeric, Character, Row State, or Expression).
modeling type
A quoted string describing the modeling type (“Continuous”, “Nominal”, “Ordinal”, “Multiple Response”, “Unstructured Text”, “None”, or “Vector”).
Format
An optional argument that sets the format type and column width. See col<<Format(<width>, <decimal places>, <"Use thousands separator">) for examples of setting other numeric format properties.
Set Values
Specifies the data in the column.
properties
The optional actions arguments are any messages that data table columns support. Action arguments are found in the Column Properties menu in the New Column dialog. Two common action arguments are Formula and Set Values.
Note
The message can also be used as the function New Column().
See Also
“Create Columns” in the Scripting Guide
“数据类型”, “建模类型”, “数值格式选项”, and “列属性” in the Using JMP book
dt<<New Data Box()
Makes a data table view in a display box tree. Useful for displaying the data table and report in one window. A data browser box is created when you send the New Data Box message to the data table object.
Example
The following script creates a data table view and report in one window. The data table is placed in a data browser box. The width of that box is set to 800 pixels. Because auto stretch is turned off, the data table view remains 800 pixels wide even if you stretch the right border of the window.
dtA = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp", invisible );
nw = New Window( "Example",
H List Box(
V List Box( dtbox = dtA << New Data Box() ),
dtA << Distribution(
Continuous Distribution( Column( :NPN1 ) ),
Continuous Distribution( Column( :PNP1 ) )
)
)
);
dtbox << Set Auto Stretching( 0, 0 ) << Set Width( 800 );
dt<<New Data View
Opens a duplicate of the data table. The second data table is identical to and linked to the original data table, so that any changes made in one are reflected in the other. Closing either data table also closes the other and all references to the data tables are deleted.
This can be useful to show an invisible data table.
dt<<New Script("name", script)
dt<<Set Property("name", script
Creates a new table property using the specified name that stores the specified script.
Use New Script() or Set Property() rather than the deprecated New Property() and New Table Property().
Example
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Set Property( "Bivariate Example", Bivariate( Y( :weight ), X( :height ), Fit Line ) );
dt<<New Table Variable("name", value)
dt<<Set Table Variable("name", value)
Creates a new table variable with the specified name and value.
dt<<Next Selected
Scrolls data table down to show the next selected row that is not already in view.
dt<<Optimize Display
Forces the data table to remeasure all of its columns and zoom to the best-sized window.
dt<<Original Order
Restores saved order of columns in dt.
dt<<Paste Multi Columns Properties
Pastes multiple lists of column properties to multiple columns. Optionally, you can specify a list of target columns instead of selecting them in the data table.
Example
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
dt << Copy Multi Columns Properties( {:MODULUS, :ELONG} );
dt2 = New Table( "test it",
New Column( "T1", numeric, continuous ),
New Column( "T2", numeric, continuous ),
New Column( "T3", numeric, continuous ),
Add Rows( 10 )
);
dt2 << Paste Multi Columns Properties( {:T1, :T3} );
// pastes the column properties from MODULUS and ELONG to T1 and T3
dt<<Previous Selected
Scrolls data table up to show the previous selected row that is not already in view.
dt<<Print Window(<"Show Dialog">)
Prints the window. If the optional argument "Show Dialog" is specified, the print window is displayed. Otherwise, the window is printed to the default printer using the current settings, and no print window is displayed.
dt<<Rename Script Group("oldname", "newname")
Renames the table script group. See “Rename a Script Group” in the Scripting Guide for an example.
dt<<Reorder By Data Type
Reorders columns in dt, row state first, then character, then numeric.
dt<<Reorder By Modeling Type
Reorders columns in dt to continuous, then ordinal, then nominal.
dt<<Reorder By Name
Reorders columns in dt to alphanumeric order by name.
dt<<Rerun Formulas
Recalculates all formula-based data table variables. Recalculations are performed in the proper dependency order.
dt<<Reverse Order
Reverses columns in dt from current order.
dt<<Revert
Reverts to the most recently saved version of dt.
dt<<Run Formulas
Performs all pending formula evaluations, including evaluations that are pending as a result of evaluating other formulas.
dt<<Run Script("name")
Finds the table property name and runs it as a JSL script.
dt<<Save("path")
dt<<Save As("path")
Saves the table under the "path" given.
For information about supported formats, see “保存和共享数据” in the Using JMP book.
dt<<Save Database("connection_information", "table_name", <Replace>)
Saves the data table to the database named using the connection and table name specified. The Replace option replaces the existing database with the current database.
dt<<Save Script to Script Window
Saves a script to reproduce the data table in a script editor window. Appends the script to any script that currently appears in the script editor.
dt<<Select All Rows
Selects all rows in the data table.
dt<<Select Columns(<column1>, <column2>, | all, ...)
Selects the specified columns (or all columns) in the data table.
dt<<Select Duplicate Rows
Selects the second and subsequent duplicate rows. If columns are selected, duplicate values are found in the rows of those columns. The duplicate values are case sensitive.
See “Select Duplicate Rows” in the Scripting Guide for examples.
dt<<Select Excluded
Selects only those rows in the data table that are currently excluded.
dt<<Select Hidden
Selects only those rows in the data table that are currently hidden.
dt<<Select Labeled
Selects only those rows in the data table that are currently labeled.
dt<<Select Randomly(p|n)
Randomly selects the given percentage p of the rows in the data table, or the number of rows n.
dt<<Select Rows({list})
Selects the rows given in the list of row numbers.
dt<<Select Script Group(<name|{group1, group2, ...}>)
Selects a table script group. If no argument is provided, all groups are selected.
dt<<Select Where(condition)
Selects the rows in dt where the condition evaluates as true.
dt<<Set Dirty(Boolean)
Marks the data table as changed, even if no changes have been made.
dt <<Set Edit Lock(<"modify cells">, <"add rows">, <"add columns">, <"delete rows">, <"delete columns">)
Prevents cells from being modified; rows from being added or deleted; and columns from being added or deleted. See “Prevent Changes to a Data Table” in the Scripting Guide for examples.
dt <<Set Cell Height(num)
Sets the cell height to the specified number of pixels.
dt<<Set Header Height(num)
Sets the column header’s height to the specified number of pixels.
dt<<Set Label Columns(column_1, ...)
Assigns the specified columns as label columns.
dt<<Set Matrix(matrix)
Inserts matrix into a data table, adding new columns and rows as necessary.
dt<<Set Name("name")
Description
Gives a "name" to the table.
Returns
The data table name as a string.
Notes
A change was made to the Set Name message so that now the new table name is returned as a string. In previous releases, Set Name returned a scriptable data table object. As a result of this change, JMP scripts might need to be updated for the desired result to be returned. For example, rewrite the following script:
dt = Open( "$SAMPLE_DATA\Big Class.jmp" ) << Set Name( "Test" );
Separate the messages so that dt represents the data table instead of “Test”:
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );
dt << Set Name( "Test" );
The result is the same as in previous releases but will run successfully in both earlier and newer versions of JMP.
dt<<Set Property("name", script)
See dt<<New Script("name", script).
dt<<Set Label Columns("name", ...)
dt<<Set Label Columns
Turns on the Label attribute for the specified columns. If no columns are listed, turns Label attribute off.
dt<<Set Row ID Width(expr)
Sets the row ID display width to the expr in pixels.
dt<<Set Row States(matrix)
Sets the row states for all rows in the data table.
dt<<Set Scroll Lock Columns("name", ...)
Locks scrolling for the specified columns. If no columns are listed, unlocks scrolling.
dt<<Set Table Variable("name", value)
See dt<<New Table Variable("name", value).
dt<<Sort(By(columns), order("Descending" or "Ascending"), Output Table Name("name"))
Description
Creates a new table ("name") by rearranging the rows of dt according to the values of one or more columns.
Returns
A reference to the sorted table.
dt<<Split (Split(column), Split by(column), Group(column), <Private> | <Invisible>, <Remaining Columns(Keep All | Drop All | Select(columns))>, <Copy formula(0|1)>, <Suppress formula evaluation(0|1)>, <Sort by Column Property("Value Ordering" {"string", "string"} | "Row Order Levels")>, <Output Table ("name")>)
Description
Un-stacks multiple rows for each Split column into multiple columns as identified by the Split by column. The Split and Split by arguments are required.
Returns
A reference to the split data table.
dt<<Stack(Stack(columns), ID(columns), Stacked(newcol), Output Table Name("name"))
Description
Creates a new table ("name") by combining the values from several columns in dt into one column newcol.
Returns
A reference to the stacked data table.
dt<<Subscribe( "keyname"(<"client">), On Delete Columns | On Add Columns | On Add Rows | On Delete Rows | On Rename Column | On Close | On Save | On Rename ( function ) )
Description
Subscribes to a data table to get messages regarding changes in the data table.
Returns
The name of the data table as a string.
dt<<Subset(Columns(columns), Rows(matrix), Linked, Table Name("name"), Copy Formula(1|0), Suppress Formula Evaluation(1|0), Sampling Rate(rate))
Description
Creates a new table ("name") from the rows that you specify in dt.
Returns
A reference to the subset data table.
dt<<Summary(<Private>, <Invisible>, Group(column), Subgroup(column), <N>, <Mean(column)>, <Std Dev(column>, <Min(column)>, <Max(column)>, <Range(column)>, <Sum(column)>, <CV(column)>, Freq(<freq column>), Weight(<weight column>), Include marginal statistics, Link to original data table(0), statistics column name format("stat(column)" | "column" | "stat of column" | "column stat")
Description
Creates a new table of summary statistics for the col that you specify, according to groups and subgroups.
Returns
A reference to the summary data table.
dt<<Suppress Formula Eval(Boolean)
Turns off automatic calculation of formulas for data table dt.
dt<<Text to Columns(Delimiters( <"separator">, <TAB>, <NEWLINE>), Columns(column 1, column 2...))
Makes a set of text columns or indicator columns from a delimited text column. NEWLINE includes the three forms \r, \n, and \r\n.
Example
dt = Open( "$SAMPLE_DATA/Consumer Preferences.jmp" );
dt << Text To Columns(
delimiter( "," ),
columns( :Brush Delimited )
);
dt<<Transpose(Columns(columns), Rows(matrix), Output Table Name("name"))
Description
Creates a new table ("name") from the rows and columns that you specify.
Returns
A reference to the transposed data table.
dt<<Ungroup Columns({col1, col1, ...})
Ungroups the columns defined in the list argument.
dt<<Ungroup Scripts("name of script group"|{script1, script2,...})
Removes the specified table scripts or group from the group. See “Ungroup Scripts” in the Scripting Guide for examples.
dt<<Unsubscribe("keyname", On Delete Columns | On Add Columns | On Add Rows | On Delete Rows | On Close | On Col Rename | All)
Releases any previous subscriptions to the data table.
dt<<Update from Database
Updates the data in the table with data reimported from the database.