dt = As Table( (0 :: 10)`, << Column Names( {"X"} ) );
// X変数を作成する
Random Reset( 12345 );
// 結果を再現できるように、乱数シードの初期値を設定する
dt << New Column( "Y",
"Continuous",
"Numeric",
Set Formula( :X * 2 + 1 + Random Normal() )
);
// Y値の計算式には乱数の要素を含む
res = []; // 結果の行列を定義する（最初は空）
For( i = 1, i <= 100, i++,
// シミュレーションの実行をループ
// 実行ごとに回帰直線をあてはめ、パラメータ推定値を保存する
bv = dt << Bivariate( Y( :Y ), X( :X ), Fit Line( 1 ), Invisible );
res |/= (Report( bv )["パラメータ推定値"][
Number Col Box( "推定値" )] << Get as Matrix)`;
// 結果を行列の下に追加していく
bv << Close Window;
// （非表示ではあるが）ウィンドウを閉じる
dt:Y << Eval Formula;
// 新しいY値を生成する
);
dtres = As Table( res, << Column Names( {"切片", "傾き"} ) );
// 結果をテーブルに出力する
dtres << Distribution( Y( :切片, :傾き ) );
// 「一変量の分布」レポートを作成する
スクリプトで中間的なステップとしての分析を実行するときに、その分析そのものをユーザに見せる必要がない場合は、invisibleオプションを使って非表示にしてください。このとき、レポート内の特定の結果だけをジャーナルまたはログに出力して、ユーザに見せることもできます。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dist = dt << Distribution( Y( :Name("身長(インチ)") ), CDF Plot( 1 ), invisible );
Report( dist )["累積確率プロット"] << Journal;
dist << Close Window;
|
•
|
次の例は、非表示の「二変量」レポートからF値を抽出し、それをログに出力します。
|
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = dt << Bivariate( x( :Name("身長(インチ)") ), y( :Name("体重(ポンド)") ), invisible );
biv << Fit Line;
r = biv << Report;
fratio = r[ColumnBox( "F値" )][1];
r << Close Window;
Show( fratio );
［テーブル］メニューにある［サブセット］、［並べ替え］、［列の積み重ね］などのオプションにinvisibleオプションを使用することもできます。次の例では、サブセットの処理を非表示にしています。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Select Where( :年齢 == 14 );
subDt = dt << Subset( invisible );
subDt << Bivariate( x( :Name("身長(インチ)") ), y( :Name("体重(ポンド)") ), Fit Line );
サブセットを使用せず、WHERE節を使用して同様の結果を得ることも可能です。
subDt << Bivariate( x( :Name("身長(インチ)") ),y( :Name("体重(ポンド)") ), Where( :年齢 == 14 ), Fit Line );