表示関数
Alpha Shape(Triangulation())
説明
指定された三角分割に対して、そこから計算されるアルファシェイプを戻す。
Border Box(<Left(pix)>, <Right(pix)>, <Top(pix)>, <Bottom(pix)>, <Sides(Boolean)>, db)
説明
別のディスプレイボックスを含むことができる枠付きのディスプレイボックスを作成する。外側の枠線と、その中身との間隔を、Left（左）、Right（右）、Top（上）、Bottom（下）というオプションで指定できます。Sidesオプションによって、周りに描く枠、枠の色（黒もしくは強調色）、背景（透明もしくは白）、背景を消すかどうかを指定できます。
戻り値
ディスプレイボックス
必須の引数
db
ディスプレイボックスオブジェクト（たとえば、テキストボックスや別のボーダーボックスなど）。
オプションの引数
Left(pix)
ピクセル数を指定する整数。
Right(pix)
ピクセル数を指定する整数。
Top(pix)
ピクセル数を指定する整数。
Bottom(pix)
ピクセル数を指定する整数。
Sides(pix)
ディスプレイボックスの設定にマップする整数。
メモ
Sidesオプションには、1*top + 2*left + 4*bottom + 8*right + 16*highlightcolor + 32*whitebackground + 64*eraseという計算式で求められた整数を指定してください。たとえば、上（top）と下（bottom）に、黒色の枠線（hightlightcolor）を描きたい場合は、1+4 = 5を指定してください。同じものを、白の背景色（whitebackground）に変えて、描きたい場合は、5+32 = 37を指定してください。
次も参照
『スクリプトガイド』のBorder Box
Box Plot Seg(<data>, <frequency>, <weight>, <Vertical(Boolean)>)
説明
指定されたデータの箱ひげ図を描くディスプレイセグメントを戻す。
戻り値
ディスプレイボックス（箱ひげ図）
オプションの引数
data
箱ひげ図を作成するデータ値。
frequency
オブザベーションの度数。
weight
オブザベーションの重み。
Vertical(Boolean)
箱ひげ図の向き。縦（1）または横（0）を指定する。
例
win = New Window( "Box Plot Segの例",
Graph Box(
Frame Size( 40, 180 ),
Y Scale( 0, 100 ),
Box Plot Seg(
[20, 30, 40], // データ
[1, 1, 3], // 度数
[1, 1, 1], // 重み
1 // 縦方向
)
)
);
Busy Light(< <<Automatic(Boolean)>, <Size(x, y)>, < <<Disable>)
説明
ビジー状態を示す、回転するイメージを作成する。
戻り値
回転するイメージ
オプションの引数とメッセージ
<<Automatic(Boolean)
イメージを回転させる。
Size(x, y)
イメージのサイズをピクセルで指定する。
<<Disable
イメージを非表示にする。
例
win = New Window( "例",
blb = Busy Light( <<Automatic( 1 ), Size( 50, 50 ) ) );
Button Box(title, script, < <<Set Icon(path)>, < <<Set Icon Location(left|right)>
説明
クリックするとスクリプト（script）を実行する、titleという名前のボタンを作成する。
戻り値
ディスプレイボックス（ボタンボックス）
必須の引数
title
引用符付き文字列、または文字列変数。
script
有効なJSLスクリプトを指定する引用符付き文字列、または文字列変数。
オプションのメッセージ
<<Set Icon("path")
引用付きパス名にあるイメージをボタン上に表示する。GIF、JPG、PNG、BMP、TIFなどの一般的なグラフィック形式に対応しています。このオプションを指定しなかった場合、テキストだけのボタンが作成されます。titleオプションの引数に空の文字列を指定し、アイコンだけを指定した場合、アイコンだけが表示されたボタンが作成されます。両方のオプションを指定すると、テキストとアイコンの両方が表示されたボタンが作成されます。その場合、アイコンは、テキストの隣に表示されます。
<<Set Icon Location("left"|"right")
ボタン上のアイコンをテキストの左または右に配置する。
例
次の例は、シンプルなボタンボックスを表示します。ユーザーがボタンをクリックすると、ログに「押されました」と出力されます。
win = New Window( "シンプルな例",
ex = Button Box( "クリックしてください" )
);
ex << Set Script( Print( "押されました" ) );
メモ
Button Boxでは改行文字が無視されます。
次も参照
『スクリプトガイド』のButton Box
Calendar Box(title, < <<Date>, < <<Min Date>, < <<Max Date>, < <<Show Time>)
説明
日時を選択できる、ポップアップカレンダーを作成する。
戻り値
ディスプレイボックス（カレンダーボックス）
必須の引数
title
引用符付き文字列、または文字列変数。
オプションのメッセージ
<<Date
現在選択されている日付。
<<Min Date
選択可能な最初の日付。
<<Max Date
選択可能な最後の日付。
<<Show Time
時間の選択を可能にする。
例
次の例は、1989年10月5日が選択されている状態のカレンダーを作成します。また、選択可能な最初の日付と最後の日付を指定し、ユーザが選択可能な期間を限定します。
New Window( "カレンダーボックスの例", cal = Calendar Box() );
date = Date MDY (10, 5, 1989);
cal << Date( date );
cal << Show Time( 0 ); // 時間は省略
/* 選択範囲の最初の日付は1989/10/5から60日前
"start"を指定して、時間の値を切り捨てる */
cal << Min Date( Date Increment(date, "Day", -60, "start" ) );
// 選択範囲の最後の日付は1989/10/05から60日後
cal << Max Date( Date Increment(date, "Day", 60, "start" ) );
cal << Set Function( Function( {this}, Print( Abbrev Date(this << Get Date()) ) ) ); // 短い表示形式で日付をログに出力
次も参照
『スクリプトガイド』のCalendar Box
Cell Plot(Y(column(s)), <X(column)>)
説明
セルプロットを表示する。
Check Box({list}, <script>, < <<Get(n)>, < <<Set(n, Boolean)>, < <<Get Selected>, < <<Enable Item(n, Boolean)>, < <<Item Enabled(check box item)>)
説明
1つまたは複数のチェックボックスを表示するディスプレイボックスを作成する。
戻り値
ディスプレイボックス（チェックボックス）
必須の引数
list
引用符付き文字列を含むリスト。
オプションの引数
script
（オプション）JSLスクリプト。
オプションのメッセージ
<<Get(n)
nで指定されたチェックボックス項目が選択されている場合は1、そうでない場合は0を戻す。
<<Set(n, Boolean)
nで指定されたチェックボックス項目を選択（1）または選択解除（0）する。
<<Get Selected
選択されているチェックボックス項目の名前を含む引用符付き文字列リストを戻す。
<<Enable Item(n, Boolean)
nで指定されたチェックボックス項目を有効（1）または無効（0）にする。無効になっているチェックボックスの状態は変更できません。
<<Item Enabled(check box item)
指定されたチェックボックス項目が有効の場合は1、そうでない場合は0を戻す。
例
「one」、「two」、「three」というラベルがついた3つのチェックボックスを作成します。その際、最初のチェックボックスを選択された状態にします。
New Window( "例", Check Box( {"one", "two", "three"}, <<Set( 1, 1 ) ) );
次も参照
『スクリプトガイド』のCheck Box
Col Box(title, display boxes)
説明
指定されたディスプレイボックスを含む列ボックスを戻す。
引数
title
列の引用符付きタイトル。
display boxes
列ボックス内に含めるディスプレイボックス。
例
win = New Window( "例",
exx = 1;
exy = 4;
exz = 8;
Table Box(
String Col Box( "strings", {"x", "y", "z"} ),
Col Box(
"boxes",
Slider Box( 0, 10, exx, Show( exx ) ),
Slider Box( 0, 10, exy, Show( exy ) ),
Slider Box( 0, 10, exz, Show( exz ) )
)
);
);
Col List Box(<Data Table(name)>, <"All"|"Character"|"Numeric">, <width(pixels)>, <"Grouped">, <MaxSelected(n)>, <nLines(n)>, <MaxItems(n)>, <MinItems(n)>, <On Change(expr)>, < <<Modeling Type("Any"|"Continuous"|
"Ordinal"|"Nominal"|Multiple Response"|"Unstructured Text"|"Vector"|
"None"|"Row State") >, < <<Set Data Type(Any|Numeric|Character)>, <script>)
説明
データテーブルの列を選択できるリストボックスを表示するディスプレイボックスを作成する。
戻り値
ディスプレイボックス（Col List Box）
オプションの引数
Data Table(name)
データテーブルの引用符付きの名前。
"All" | "Character" | "Numeric"
現在のデータテーブルのすべての列をリストに追加する。"All"を省略すると、“オプション”ラベルの付いた空の列リストボックスが表示されます。“オプション(文字)”を表示する場合は"Character"を指定します。“オプション(数値)”を表示する場合は"Numeric"を指定します。
width(pixels)
リストボックスの幅をpixelsで設定する。pixelsはピクセル数を示す数値。
"Grouped"
グループ化されている列がある場合、Col List Boxの中でもグループ化して表示する。
MaxSelected(n)
選択できる項目が1つだけかどうかを設定する。n<1の場合、nは無視される。
nLines(n)
リストボックスの長さをn行に設定する。nは整数。
script
スクリプト。
MaxItems(n)
リストに追加できる列の数をn個に制限する。
MinItems(n)
リストに少なくともn個の列を追加するように求める。たとえば、n=2の場合、Col List Boxの最初の2つの項目に、「必須」、「必須(文字)」、もしくは「必須(数値)」と表示される。
On Change(expr)
リストの選択内容に変更が生じるたびに式を評価する。この引数を持つ2つの列リストボックスの間をドラッグすると、両方の式が評価されます。ドラッグ先の式がまず評価され、その後ドラッグ元の式が評価されます。
オプションのメッセージ
<<Set Tips({Tip text 1, Tip text 2, ...})
リストボックス内の項目にツールヒントを設定する引用符付き文字列。引用符付きヌル文字列または空のリストを指定した場合、ツールヒントは設定されません。リストボックス内の項目のリストよりも、指定したリストの方が短い場合、最後のツールヒントテキストが、リストボックス内の残りのリスト項目にも使用されます。
<<Set Tip(Tip text)
Set Tips()関数で設定されたツールヒントを上書きする引用符付き文字列。ボックス自体にヒントが設定されている場合、個々のリスト項目のヒントを設定することはできません。
Set Tip()を引数未指定で使用すると、リストボックスのヒントが消去され、各リスト項目のツールヒントが表示されるようになります。
メモ
– MaxSelected(n)の引数は、項目を1つだけ選択できるか、または複数選択できるかだけを決定するものです。2つ以上の列を強制的に選択させるものではありません。
– 特殊な尺度の列は、その尺度の列を明示的に受け入れると指定している場合のみ割り当てることができます。
次も参照
『スクリプトガイド』のCol List Box
Col Span Box(title, display box args)
説明
テーブルボックスに、列見出しを作成する。最上部の列見出しは、2つの子列ヘッダにまたがります。
戻り値
ディスプレイボックス（Col Span Box）
引数
title
ボックスに表示されるタイトル。
display box args
ディスプレイボックス。
例
win = New Window( "Col Span Box",
<<Modal,
Table Box(
Col Span Box(
"信頼限界",
neb = Number Col Edit Box( "上側限界", [0, 0] ),
Number Col Edit Box( "下側限界", [0, 0] )
)
)
);
次も参照
『スクリプトガイド』のCol Span Box
Combo Box({items <(tip string)>, ...}, <script>)
説明
ドロップダウンリストを表示するためのディスプレイボックスを作成する。
戻り値
ディスプレイボックス（コンボボックス）
引数
items
ユーザが選択できる項目。
tip string
ツールチップのテキストを指定する引用符付き文字列。
script
（オプション）JSLスクリプト。
次も参照
『スクリプトガイド』のCombo Box
Context Box(display box, ...)
説明
変数や式のスコープを限定するディスプレイボックスを定義する。各コンテキストボックスは、独立して、個別に評価・実行されます。
戻り値
ディスプレイボックス
引数
任意の数のディスプレイボックス
Contour Seg(Triangulation, [levels], <zColor([colors]|{colors}, <"Cycle Colors"|"Interpolate Colors">)>, <"Fill"|"Fill Between"|"Fill Below"|"Fill Above">, <Transparency([]|t)>)
説明
三角分割の等高線を表すディスプレイセグメントを戻す。
必須の引数
Triangulation
三角要素座標に含む列。
[levels]
等高線の値を示す行列。
オプションの引数
zColor([colors]|{colors}
リストまたは行列として指定した各水準の色。
"Cycle Colors"|"Interpolate Colors"
このうち、"Cycle Colors"は、色を交互に切り替える（たとえば、赤、緑、赤、緑）。一方、"Interpolate Colors"では、例えば、最初の等高線が赤、最後の等高線が緑である場合には、その間にある等高線には、赤と緑を混ぜたグラデーションが使用される。
"Fill Below"|"Fill Between"|"Fill Above"|"Fill"
このうち、"Fill Below"は、線の下の領域を塗りつぶす。"Fill Between"は、線の間の領域を塗りつぶす。"Fill Above"は、線の上の領域を塗りつぶす。"Fill"は、"Fill Above"と同様に動作しますが、Fillのオプションが指定されていない場合はデフォルトで線を表示します。
Transparency([]|t)
透明度を数値または行列で指定する。
例
dt = Open( "$SAMPLE_DATA/Cities.jmp" );
tri = Triangulation( X( :X, :Y ), Y( :POP ) );
{xx, yy} = tri << Get Points();
win = New Window( "Contour Segの例",
g = Graph Box(
X Scale( Min( xx ) - .1, Max( xx ) + .1 ),
Y Scale( Min( yy ) - .1, Max( yy ) + .1 ),
Contour Seg(
tri,
[0, 400, 1000, 2000, 9000],
zColor( 5 + [64 32 0 16 48] ),
Transparency( [1, 1, 1, 1, 1] )
)
)
);
メモ
三角分割は、2つのXを使って計算され、Yは、各位置で定義された連続尺度の変数です。この例の[levels]は、等高線を描く人口の値を設定しています。Fillの引数が指定されている場合、塗りつぶされる領域は、[level1, level2]、[level2, level3]...[level-n]です。
Current Journal()
説明
現在のジャーナルの最上位のディスプレイボックスへの参照を戻す。
戻り値
現在のジャーナルの最上位のディスプレイボックスへの参照
次も参照
『スクリプトガイド』のCurrent Journal
Current Report()
説明
現在のレポートウィンドウの最上位のディスプレイボックスへの参照を戻す。
戻り値
現在のレポートウィンドウの最上位のディスプレイボックスへの参照
Current Window()
説明
現在のウィンドウへの参照を戻す。
Data Filter Context Box(display box)
説明
表示ツリーに含まれるローカルデータフィルタの範囲を定義するディスプレイボックスを戻す。Data Filter Context Boxとデータフィルタを階層形式で配置することで、Data Filter Context Boxに含まれるプラットフォームまたはボックス間でフィルタを共有できます。
次も参照
『スクリプトガイド』のフィルタリングを行うディスプレイボックス
Data Filter Source Box(display box)
説明
どのグラフが選択フィルターの「ソース」であるかを定義する。Data Filter Source Boxの中あるレポートで選択された行が、同じData Filter Context Box内にある他のレポートの分析対象となります。
次も参照
『スクリプトガイド』のフィルタリングを行うディスプレイボックス
Data Table Box(data table)
説明
指定されたデータテーブルを表示するTable Boxを戻す。
例
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
win = New Window( "例", Data Table Box( dt ) );
Data Table Col Box(column)
説明
指定されたデータテーブルを表示する列ボックスを戻す。
例
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
win = New Window( "例",
Table Box( Data Table Col Box( :名前 ), Data Table Col Box( :"身長(インチ)"n ) )
);
Dialog(contents)
説明
Dialogは廃止されました。Dialog関数の代わりに、Modal引数とともにNew Window()関数を使用してください。
次も参照
『スクリプトガイド』の廃止されるDialogをNew Windowに変換する
Excerpt Box(report, subscripts)
説明
レポートから一部分を抜粋し、その抜粋したディスプレイボックスを戻す。レポートの番号をreportで指定し、ディスプレイのリストをsubscriptsで指定します。subscriptsに指定する番号は、抜粋したディスプレイを除いた後の番号。
Expr As Picture(Expr(...), <Width(pixels)>)
説明
計算式エディタに表示される式と同じ形式で、expr()をイメージに変換する。
戻り値
イメージへの参照
必須の引数
Expr(...)
イメージとして表示できる有効なJSL式をexpr()の中に挿入。
オプションの引数
Width(pixels)
ボックスの幅をpixに設定する。pixはピクセル数を示す数値。
次も参照
『スクリプトガイド』のピクチャーオブジェクト
Filter Col Selector(<Data Table(name)>, <Width(pixels)>, <nLines(n)>, <script>, <OnChange(expr)>)
説明
列名のリストを含むディスプレイボックスを戻す。列のフィルタリングを設定できる。
Get Project(title|index|display box|window)
説明
プロジェクトを戻す。
例
次の例は、さまざまなプロジェクトのウィンドウタイトルを取得する方法を示します。
Get Project( 1 ) << Get Window Title;
// 開いている最初のプロジェクト
Get Project( "マイプロジェクト" ) << Get Window Title;
// 「マイプロジェクト」という名前の最初のプロジェクト
Get Project( display box ) << Get Window Title;
// 指定したディスプレイボックスの親プロジェクト
Get Project List()
説明
現在開いているすべてのプロジェクトをリストで戻す。
例
Get Project List() << Get Window Title;
// 開いているすべてのプロジェクトのタイトルのリスト
Get Window(<Project(title|index|display box|window)>, <Type(string)>, title|index|display box)
説明
指定したタイトル、通し番号、またはディスプレイボックスを持つウィンドウへの参照を戻す。Get Window()をプロジェクトの中で実行した場合、現在のプロジェクトのウィンドウが戻されます。
オプションの引数
Project
プロジェクトのタイトル（引用符付き文字列）、通し番号、ディスプレイボックス、またはウィンドウを指定する。
Type(string)
検索対象を特定のウィンドウタイプに限定するには、Type ()引数と、"Data Tables"、"Journals"、"Reports"、"Dialogs"のいずれかの引用符付き文字列を使用します。
例
次の例は、さまざまなウィンドウのウィンドウタイトルを取得する方法を示します。
Get Window( 1 ) << Get Window Title;
// 現在のプロジェクトの最初のウィンドウ
Get Window( "Big Class" ) << Get Window Title;
// 現在のプロジェクトの「Big Class」ウィンドウ
Get Window( ob ) << Get Window Title;
// 現在のプロジェクトにある指定のディスプレイボックスの親ウィンドウ
Get Window( Project(), 1 ) << Get Window Title;
// 最初のウィンドウ、プロジェクトなし（グローバルスコープ）
Get Window( Project( myProject ), "Big Class" << Get Window Title;
// 指定したプロジェクトの「Big Class」ウィンドウ
Get Window List(<Project(title|index|display box|window),><Type(string)>)
説明
現在開いているウィンドウのリストを戻す。プロジェクト内で実行された場合、Get Window List()は、現在のプロジェクトで開いているウィンドウへの参照を戻します。現在のプロジェクト以外のプロジェクトから、開いているウィンドウのリストを取得するには、Project()引数を使用します。検索対象を特定のウィンドウタイプに限定するには、Type ()引数と、"Data Tables"、"Journals"、"Reports"、"Dialogs"のいずれかの引用符付き文字列を使用します。
オプションの引数
Project
プロジェクトのタイトル、通し番号、ディスプレイボックス、またはウィンドウを指定します。
Type
検索対象を特定のウィンドウタイプに限定するには、Type ()引数と、"Data Tables"、"Journals"、"Reports"、"Dialogs"のいずれかの引用符付き文字列を使用します。
例
Get Window List() << Get Window Title;
// 現在のプロジェクト内で開いているウィンドウのリスト
Get Window List( Type( "Reports" ) ) << Get Window Title;
// 現在のプロジェクト内で開いているレポートのタイトルのリスト
Get Window List( Project( 0 ), Type( "Reports" ) ); // 位置引数
// プロジェクトの外で開いているレポートのタイトルのリスト
Get Window List( 2 );
// 2番目のウィンドウリスト
Global Box(global)
説明
グローバル変数（global）の値を直接編集するボックスを作成する。
次も参照
『スクリプトガイド』のGlobal Box
Graph()
Graph Box(properties, script)を参照してください。
Graph 3D Box(properties)
説明
3次元散布図を含むディスプレイボックスを作成する。
戻り値
ディスプレイボックス
引数
properties
プロパティには、Frame Size(x, y)、Xname("title")、Yname("title")、Zname("title")がある。
メモ
この機能は試験段階です。
Graph Box(properties, script)
Graph(properties, script)
説明
X軸およびY軸のあるグラフを作成する。
戻り値
ディスプレイボックス（グラフボックス）
引数
properties
引数には、Title("title")、XScale(low, high)、YScale(low, high)、FrameSize(h, v)、XName("x")、YName("y")、SuppressAxesがある。
script
グラフボックスで実行するスクリプト。
次も参照
『スクリプトガイド』の独自のグラフの作成とカスタマイズ
『スクリプトガイド』のGraph Box
H Center Box(<child box>)
オプションの引数で指定した子ディスプレイボックスを含むディスプレイボックスを戻す。子ディスプレイボックスを横方向のスペースの中央に配置します。
H List Box(<Align("center"|"bottom")>, display box, ...)
説明
ディスプレイボックスを作成し、その中に別のディスプレイボックスを横に並べて表示する。
引数
Align("center"|"bottom")
ディスプレイボックスの位置を、中央揃え（center）または下揃え（bottom）に指定する。デフォルトでは、下揃えで配置されます。
display box
リストボックスに含める任意の数のディスプレイボックスを指定する。
次も参照
『スクリプトガイド』のH List BoxとV List Box
H Scroll Box(<Size(h)>, display box)
説明
横方向のスクロールバーがついたディスプレイボックスを戻す。中により大きな子ボックスを配置することができます。
引数
Size(h)
スクロールバーの横方向の長さ。
メモ
flexible引数は廃止されています。代わりに、Set Stretchを使用してください。例については、
V Scroll Box(<Size(v)>, display box)を参照してください。
H Sheet Box(<<Hold(report), display boxes)
説明
引数に指定された複数のディスプレイボックスを横方向に配置したディスプレイボックスを戻す。<<Hold()メッセージは、抜粋元となるレポートをどのシートが保持するかを示す。
次も参照
『スクリプトガイド』のH Sheet BoxとV Sheet Box
H Splitter Box(<Size(h, v)>, display box, ...)
説明
引数に指定された複数のディスプレイボックスを横方向（パネル）に配置し、分割線で仕切ったディスプレイボックスを戻す。ユーザは分割線をドラッグしてパネルのサイズを変更できます。
必須の引数
display box
分割線ボックスには任意の数のディスプレイボックスの引数を設定できる。
オプションの引数
Size(h, v)
Splitter Boxのサイズをピクセルで指定する。このサイズは外側のSplitter Box用です。内側のディスプレイボックスのサイズは、外側のSplitter Boxの幅と高さに合わせて変更されます。
オプションのメッセージ
<<Size(n)
最後のパネルの比率を指定する。<<Size(.25)は、最後のパネルのサイズを分割線ボックスの高さ（H Splitter Boxの場合は幅）の25%に変更します。
<<Set Sizes({n, n})
各パネルの比率を指定する。db<<Set Sizes({.75, .25})は、最初のパネルのサイズを分割線ボックスの高さ（H Splitter Boxの場合は幅）の75%に変更し、2番目のパネルのサイズを同25%に変更します。
<<Close Panel(n, <Boolean>)
指定したパネルを閉じる。<<Close Panel(2)は、2番目のパネルを閉じます。3つ以上のパネルがある場合は、2番目のブール値を含める必要があります。その値により、閉じたパネルによって余ったスペースを埋めるパネルを指定します。
– <<Close Panel(2,0)は、2番目のパネルを閉じ、その後のパネルが余ったスペースを埋めます。
– <<Close Panel(2,1)は、2番目のパネルを閉じ、その前のパネルが余ったスペースを埋めます。
<<Open Panel(n, <Boolean>)
指定したパネルを開く。3つ以上のパネルがある場合は、2番目のブール値を含める必要があります。前述の<<Close Panelと同様に機能します。パネルは初期状態ですべて開いているため、<<Open Panelは<<Close Panelを使用した後にのみ使用します。
<<Get Sizes()
各パネルの比率をリストで戻す。
次も参照
『スクリプトガイド』のH Splitter BoxとV Splitter Box
Hier Box(text, Hier Box(...), ...)
説明
テキスト（text）が含まれているツリーのノードを作成する。これは、特性要因図プラットフォームの出力と同じです。Hier Boxは別のHier Boxを含めることができ、ツリーを作成できます。テキストは、引用符付き文字列またはText Edit Boxでもかまいません。
Hist Seg([data], <[freq column]>, <[weight column]>, <Vertical(Boolean)>, <Row States()>
説明
ヒストグラムセグメントを戻す。
必須の引数
data
行列形式のデータ。
オプションの引数
freq column
行列形式の度数列。
weight column
行列形式の重み列。
Vertical(Boolean)
デフォルトで（または1に設定されている場合）、ヒストグラムを縦に表示する。値が0に設定されている場合は、ヒストグラムを横に表示する。
Row States
データテーブル参照または行の属性を指定する。
Icon Box(name)
説明
アイコンを含むディスプレイボックスを作成する。引数で指定する名前（name）には、Popup 
、Locked 
、Labeled 
、Sub 
、Excluded 
、Hidden 
、Continuous 
、Nominal 
、Ordinal 
があります。引数には、イメージへのパスを指定することもできます。
引数
name
JMPのアイコン名またはアイコンのパスを示す引用符付き文字列。
例
Icon Box( "Nominal" )は、名義尺度アイコンを含むディスプレイボックスを作成します。
Icon Box( "$SAMPLE_IMAGES/pi.gif" )は、pi.gifサンプルイメージを挿入します。
メモ
– WindowsとmacOSの両方で使用されているアイコンと、その他のアイコンは、それぞれのプラットフォームでのみ使用可能です。
– Built-In JMP Iconsというアドインがあり、いろいろなコンテキストでアイコンがどのように表示されるかを確認することができます。
このアドインは、https://community.jmp.com/t5/JMP-Add-Ins/Built-In-JMP-Icons/ta-p/42251からダウンロードできます。
If Box(Boolean, display boxes)
説明
条件によって中身が表示されるディスプレイボックスを作成する。
引数
Boolean
1はIf Boxの内部にあるディスプレイボックスを表示し、0である場合は表示しない。
display boxes
任意のディスプレイボックスツリー。
If Seg(<State(Boolean)>)
説明
セグメントの子を表示または非表示にするディスプレイセグメントを戻す。
引数
State(Boolean)
子のディスプレイセグメントを表示する（1）か非表示にする（0）かを決定する。
例
lines = [30 20 80 70, 10 90 90 10, 40 20 60 30];
win = New Window( "Lines Segの例",
g = Graph Box( If Seg( true, <<Append( Lines Seg( lines ) ) ) )
);
Journal Box(string)
説明
引用符付き文字列から生成されるジャーナルを表示するディスプレイボックスを作成する。手動でジャーナルテキストを生成することはお勧めしません。
次も参照
『スクリプトガイド』のJournal Box
Line Seg(x, y, <Row States(dt|dt, [rows]|dt, {{rows}, ...}|{row states})>, <Sizes(s)>)
説明
指定のxとyの値について、つながった線分を描くディスプレイセグメントを作成する。オプションの第3引数では、データテーブルの行属性を使用するか、またはそれとは別のものを使用するかを指定できます。
Lines Seg([x1 y1 x2 y2, ...])
説明
指定のxとyの値について、複数の線分を描くディスプレイセグメントを戻す。
Lineup Box(<nCol(n)>, <Spacing(pixels, <vspace>), display boxes, ...)
説明
n列にボックスを整列させて表示するディスプレイボックスを作成する。
次も参照
『スクリプトガイド』の項目の整列
List Box({item, ...}, <Width(pixels)>, <maxSelected(n)>, <nLines(n)>, <script>)
説明
複数の項目（引用符付き文字列）を含むリストボックスを表示するディスプレイボックスを作成する。引数itemには、項目名の文字列を含むリストを指定します。もしくは、項目名の文字列と、尺度または並べ替え順序を示す引用符付き文字列を含むリストのリストを指定します（なお、項目名では、デフォルトで大文字・小文字が区別されます）。後者の場合、リストボックス内の項目の横に、尺度または並べ替え順序のアイコンが表示されます。
Marker Seg(x, y, <Row States(dt|dt, [rows]|dt, {{rows}, ...}|{row states})>, <Sizes(s)>)
説明
指定されたxとyのすべての値にマーカーを描くディスプレイセグメントを作成する。オプションの第3引数では、データテーブルの行属性を使用するか、またはそれとは別のものを使用するかを指定できます。
Matrix Box(x)
Matrix Box(matrix, < <<Column Names(col1, col2, ...)>, < <<Row Names(row1, row2, ...)>)
説明
与えられた行列（matrix）を表示する。列と行の名前は引用符付き文字列です。
Mouse Box(display box arguments)
説明
ドラッグ＆ドロップ、マーキング、クリック、トラックなどのマウス動作に対するJSLコールバックを作成するボックスを戻す。
引数
display box arguments
Text BoxやButton Boxなど、ユーザが操作できるオブジェクトを指定する。［ヘルプ］メニューの［スクリプトの索引］を参照してください。
次も参照
『スクリプトガイド』のMouse Box
Move to Project(<Source(project)|Destination(project)>, <Windows({list of windows to move})>)
説明
1つまたは複数のウィンドウをプロジェクトから外へ（またはプロジェクトの中に）、またはプロジェクト間で移動させる。
引数
Source(project)
移動させたいウィンドウを含むプロジェクト。
Destination(project)
移動先のプロジェクト。
Windows({list of windows to move})
移動するウィンドウのリスト。これを省略した場合、すべてのウィンドウが移動します。windows引数にデータテーブルを指定した場合、そのデータテーブルから作成されたすべてのレポートも移動します。レポートを指定した場合も、そのレポートのもととなったデータテーブルとそのテーブルから作成されたすべてのレポートが移動します。windows引数の中で指定するのはデータテーブルまたはレポートの名前です。
例
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
report = dt << Run Script( "Bivariate" );
project = New Project();
// レポートとデータテーブルを新しいプロジェクトに移動させる
Move to Project( Destination( project ), Windows( {report} ) );
New Image()
New Image(width, height)
New Image(filepath)
New Image(Open(url) )
New Image(picture)
New Image(matrix)
New Image(rgb|r|rgba, {matrix, ...})
説明
新しいイメージを作成する。このイメージは、JSLで編集できます。有効な形式は、png、bmp、jpeg、jpg、tiff、tif、gifです。
戻り値
イメージ
引数
すべての引数セットはオプションだが、それぞれのセット内ではすべての引数が必須。
width, height
イメージの幅と高さをピクセルで設定する。
filepath
イメージへの引用符付きファイルパス。
Open(url)
指定したURLパスにあるイメージを開きます。
picture
JSLピクチャーオブジェクト。
matrix
イメージをJSLカラーのピクセルの配列で示したもの。
rgb|r|rgba, {matrix, ...}
チャネルを指定し（"rgb"、"r"、または"rgba"）、各チャネルの値の行列（0.0-1.0）を指定する。例:
New Image( "r", [r matrix] );
New Image( "rgb", {[r matrix], [g matrix], [b matrix]} );
New Image( "rgba", {[r matrix], [g matrix], [b matrix], [a matrix]} );
New Project(arguments)
説明
新しいプロジェクトを作成する。
引数
<<Add Bookmarks({<File(path)>, <Folder(path, Expanded(Boolean)>)>, <Group(name, <Expanded(Boolean)>, {contents}>)
プロジェクトで頻繁に使用されるファイルをブックマークに追加する。引数は、ブックマーク項目のリストで、それぞれをFile()、Folder()、またはGroup()を使って指定します。Group()には、File()、Folder()、およびGroup()を子として指定できます。
<<Reset Layout
プロジェクトのウィンドウレイアウトをデフォルトの状態に戻す。
<<Run Script
プロジェクトの中に表示するデータテーブルとレポートを指定する。
<<Save(<path>)
プロジェクトを保存する。プロジェクトを特定の場所に保存するには、引用符付きのパスおよびファイル名を含めます。Save Asはエイリアスです。
<<Set Bookmarks({<File(path)>, <Folder(path, Expanded(Boolean)>)>, <Group(name, <Expanded(Boolean)>, {contents}>)
プロジェクトのブックマークを設定する。引数は、ブックマーク項目のリストで、それぞれをFile()、Folder()、またはGroup()を使って指定します。Group()には、File()、Folder()、およびGroup()を子として指定できます。
<<Set Layout
プロジェクトのウィンドウレイアウトを設定する。
<<Show Bookmarks
ブックマークの表示／非表示を切り替える。
<<Show Log
ログの表示／非表示を切り替える。
<<Show Window List
ウィンドウリストの表示／非表示を切り替える。
例
次の例は、「BigClass.jmp」と2つのレポートを含むプロジェクトを作成します。
project = New Project();
project << Run Script(
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Run Script( "二変量の関係(二変量) " );
dt << Run Script( "一変量の分布" );
);
次も参照
『スクリプトガイド』のプロジェクトの作成
『スクリプトガイド』のブックマークのグループの作成
New Window(title, <arguments>, display box)
説明
必須の引用符付きタイトルとディスプレイボックスツリーを含む新しいウィンドウを作成する。
オプションの引数
<<Script(<script>)
スクリプトウィンドウを作成する。オプションで、スクリプトウィンドウに表示するスクリプトを、引用符付き文字列"script"で指定できます。
<<Journal
空のジャーナルを作成する。
<<Size Window(x, y)
新しいウィンドウの高さと幅を指定する。
<<Modal
新しいウィンドウをモーダルウィンドウにする。このウィンドウを閉じるまでJMP内で他のアクションを実行することができなくなります。［OK］ボタンまたは［キャンセル］ボタンを追加しなかった場合、それらは自動的に追加されます。メモ: この引数を使用する場合は、ウィンドウタイトルのすぐ後に続く第2引数として指定します。使用できるモーダルウィンドウの引数は次のとおりです。
– <<On Open(expr)は、ウィンドウの作成時に式（expr）を実行する。
メモ: データテーブルでは、別のプログラムを実行するOn Open（またはOnOpen）スクリプトは、実行されません。このスクリプトが実行されるタイミングを制御する必要がある場合は、環境設定の［OnOpenスクリプトの評価］を設定してください。
– <<On Close(expr)は、ウィンドウが閉じるときに式（expr）を実行する。ウィンドウを閉じることができない場合は0を返します。
– <<On Validate(expr)は、［OK］ボタンが押されたときに式（expr）を実行する。Trueを返した場合はウィンドウが閉じ、それ以外の場合、ウィンドウは開いたままになります。
– <<Return Resultは、ウィンドウが閉じるときの戻り値を、廃止されたDialog()関数の戻り値と一致するよう変更する。
Show Toolbars(Boolean)
ツールバーの表示／非表示を切り替える。デフォルト値は1です。（Windowsのみ）。
Show Menu(Boolean)
メニューバーの表示／非表示を切り替える。デフォルト値は1です。（Windowsのみ）。
Suppress AutoHide(Boolean)
メニューおよびツールバーの自動非表示機能の使用／不使用を切り替える。デフォルト値は1です。（Windowsのみ）。
メモ
Dialog()は廃止されました。Dialog関数の代わりに、Modal引数とともにNew Window()関数を使用してください。
次も参照
『スクリプトガイド』の廃止されるDialogをNew Windowに変換する
Number Col Box(title, numbers)
説明
引用符付き文字列で指定されたタイトル（title）をつけた列を作成し、リストまたは行列の形で与えられた数値を挿入する。
Number Col Edit Box(title, {numbers}|[numbers])
説明
引用符付き文字列で指定されたタイトル（title）をつけた列を作成し、リストまたは行列の形で与えられた数値を挿入する。この関数によって作成された列の数値は、編集できます。
Number Edit Box(initial value, <width>)
説明
initial value引数で指定された数値が入力された数値ボックスを作成する。
戻り値
ディスプレイボックスオブジェクト
引数
initial value
初期値として使用する数値。日付または時間の形式を使用すると、日付または時間のセレクタウィンドウが作成されます。
<width>
ボックスの幅を文字数で設定する。
次も参照
『スクリプトガイド』のNumber Edit Box
Outline Box(title, display box, ...)
説明
指定された複数のディスプレイボックスを含んだ、title（引用符付き文字列）という名前の新しいアウトラインを作成する。
次も参照
『スクリプトガイド』のOutline Box
Page Break Box()
説明
ウィンドウが印刷された場合、改ページを強制するディスプレイボックスを作成する。
Panel Box(title, display box)
説明
指定されたタイトル（title）のラベルをもつパネルのディスプレイボックスを作成する。そのパネルには、複数のディスプレイボックスを含めることができます。
次も参照
『スクリプトガイド』のPanel Box
Picture Box(Open(picture), format)
説明
グラフィックピクチャーオブジェクトを含むディスプレイボックスを作成する。
戻り値
ディスプレイボックスへの参照
引数
Open(picture)
ピクチャを含むディレクトリを開く。
format
グラフィックファイルの形式を指定する。JMPでピクチャーを開く形式を指定します。この引数を指定しないと、ピクチャーはデフォルトのグラフィックプログラムで開かれます。有効な形式は、引用符付き文字列の"png"、"bmp"、"jpeg"、"jpg"、"tiff"、"tif"、"gif"です。
例
New Window( "例",
Picture Box( Open( "$SAMPLE_IMAGES/pi.gif", gif ) ) );
Platform(data table, script)
説明
指定されたスクリプトを指定されたデータテーブルのコンテキストにおいて評価する。
戻り値
表示ツリーに埋め込むための結果のディスプレイボックス
例
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
win = New Window( "Platformの例",
H List Box(
Platform(
dt,
Bubble Plot(
X( :"体重( ポンド )"n ),
Y( :"身長( インチ )"n ),
Sizes( :年齢 ),
Title Position( 0, 0 )
)
),
Platform(
dt,
Bubble Plot(
X( :"体重( ポンド )"n ),
Y( :年齢 ),
Sizes( :"身長( インチ )"n ),
Title Position( 0, 0 )
)
)
)
);
Plot Col Box(title, numbers)
説明
数字（numbers）をグラフ化したディスプレイボックスに、引用符付き文字列で指定されたタイトル（title）を付けて戻す。数字にはリストまたは行列を指定できます。
Poly Seg(x values, y values)
説明
指定された（x values, y values）座標を通るポリゴン（多角形）を描くディスプレイセグメントを戻す。
例
x = [10, 50, 90];
y = [10, 90, 10];
win = New Window( "Poly Segの例",
g = Graph Box( Poly Seg( x, y ) ) );
frame = g[FrameBox( 1 )];
seg = (frame << Find Seg( "Poly Seg" ));
Popup Box({command1, script1, command2, script2, ...})
説明
赤い三角形ボタンのメニューを作成する。引数のリストには、コマンドの文字列と実行されるスクリプトをペアで指定します。まず、引用符付きコマンド文字列を指定し、その後にそのコマンドを選択したときに評価される式を指定します。コマンドが空の場合は、区切り線が挿入されます。
メモ
Altキーを押しながら赤い三角ボタンのメニューを右クリックすると、コマンドのチェックボックスがあるウィンドウが表示されます。
次も参照
『スクリプトガイド』のPopup Box
『JMPの使用法』のJMPレポートの表示オプション
Radio Box({item, ...}, <script>)
説明
一連のラジオボタンを表示するディスプレイボックスを作成する。項目は引用符付き文字列です。ラジオボタンが選択されるたびに、オプションのスクリプトが実行されます。
次も参照
『スクリプトガイド』のRadio Box
Range Slider Box(minValue, maxValue, lowVariable, highVariable, script)
説明
Range Slider Box()は、最小値（minValue）から最大値（maxValue）までの範囲スライダを表示したディスプレイボックスを戻す。2つのスライダの位置が変化すると、その値がlowVariableとhighVariableに代入され、スクリプトが実行されます。
戻り値
ディスプレイボックス（範囲スライダボックス）
引数
minValue, maxValue
スライダの最小値および最大値となる数値。
lowVariable
最小値側のスライダによって設定・変更される変数。
highVariable
最大値側のスライダによって設定・変更される変数。
script
スライダボックスの移動に伴って実行される任意の有効なJSLコマンド。
Report(obj)
説明
プラットフォームオブジェクト（obj）の表示ツリーを戻す。同じ処理は、次のように、メッセージとしてプラットフォームに送っても行えます。
obj<<Report
Scene Box(x size, y size)
説明
3Dグラフィック用のシーンボックスを作成する。ボックスの横幅はx、高さはyに設定される。
Scene Display List
説明
3次元グラフィックのためのディスプレイリストを戻す。
例
ex = Scene Display List();
ex << Color( .9, .9, .9 );
ex << Text( center, middle, .3, "Hello World" );
exScene = Scene Box( 600, 600 );
exScene << Background Color( 0 );
exScene << Show Arcball( always );
New Window( "Samples/Scripts/Scene3Dにある「HelloWorld.jsl」を参照", exScene );
exScene << Perspective( 45, .2, 20 );
exScene << Translate( 0.0, 0.0, -4.5 );
exScene << Arcball( ex, 1.5 );
exScene << Update;
Script Box(<script>, <language>, <width>, <height>)
説明
引用符付き文字列で指定されたスクリプト（script）を含む編集ボックスを作成する。このボックスはスクリプトウィンドウの一種で、JSLを編集・実行できます。
オプションの引数
script
スクリプトボックスに表示する引用符付き文字列を指定する。
language
指定した言語に対応した構文の強調表示を可能にする引用符付き文字列。有効な言語は、"JSL"、"Text"、"SAS"、"SAS Output"、"SASLog"、"R"、"MATLAB"、"JavaScript"、"C"、"SQL"、"Python"、"JSON"、"XML"です。
width
スクリプトボックスの幅を指定する整数。
height
スクリプトボックスの高さを指定する整数。
例
// JSON
New Window( "JSON",
Script Box(
"{\!"a\!":1,\!"b\!":\!"test\!"}",
"JSON"
)
);
Scroll Box(<Size(h,v)>, display box, ...)
説明
スクロールバーを使って表示する、より大きな子ボックスを配置したディスプレイボックスを作成する。
戻り値
スクロールボックスオブジェクトへの参照
必須の引数
display box
スクロールボックスには任意の数のディスプレイボックスの引数を設定できる。
オプションの引数
Size(h,v)
h引数およびv引数で、ボックスのサイズをピクセル単位で指定する。
メモ
スクロールボックスオブジェクトに次のメッセージを送ることによって、背景色を設定できます。
<<Set Background Color( {R, G, B} | <color> )
Flexible引数は廃止されています。代わりに、Set Stretchメッセージを使用してください。例については、V Scroll Box(<Size(v)>, display box)を参照してください。
横方向（h）と縦方向（v）のスクロールについてブール値のフラグを設定し、スクロールバーを有効（1）または無効（0）にすることができます。所定の方向のスクロールが無効な場合、スクロールボックスはその方向については標準のコンテナ同様の働きをします。
<<Set Scrollers (h, v)
スクロールに関する現在のこれらのフラグを得るには、次のメッセージを使用します。
<<Get Scrollers
スクロールバーのスクローラーの横方向（h）と縦方向（v）の位置（ピクセル単位）を設定するには、次のメッセージを使用します。
<<Set Scroll Position (h,v)
現在のこれらのスクロール位置を得るには、次のメッセージを使用します。
<<Get Scroll Position
横方向と縦方向のスクロール範囲に関する現在の上限位置を得るには、次のメッセージを使用します。
<<Get Scroll Extents
例
次の例は、所定の設定のスクロールボックスを含むウィンドウを表示します。
win = New Window( "例",
sb = Scroll Box(
Size( 150, 75 ),
List Box(
{"First Item", "Second Item",
"Third Item", "Fourth Item",
"Fifth Item"},
width( 200 ),
max selected( 2 ),
nLines( 6 )
)
)
);
win << Set Window Size( 300, 200 );
sb << Set Scrollers( 1, 1 ); // 両方向のスクロールバーを有効化
// スクロールバー上のスクローラーの位置を指定
sb << Set Scroll Position( 0, 20 );
Shape Seg( {Path(path), ...}, <Row States(dt|dt,[rows]|dt,{{rows}, ...}|{row states})>)
説明
さまざまな形状を持つディスプレイセグメントを戻す。
必須の引数
Path
Nx3行列または文字列でパスを指定する。行列の場合は、x座標、y座標、およびパス内の各点のフラグの3列の構成で指定する。フラグの値には、0（コントロール点）、1（移動）、2（線分）、3（3次ベジエ曲線）または負の値（点がパスの終点でもある場合）を指定できます。パスを文字列で指定する場合は、SVG構文を用います。
オプションの引数
Row States
データテーブル参照、およびオプションで行または現在の行の属性を指定する。
例
win = New Window( "Shape Segの例",
Graph Box(
Shape Seg(
{Path( [10 10 1, 10 70 0, 70 70 0, 70 10 -3] ),
Path( "M20,20 C20,60 60,60 60,20 Z" )},
Row States( {Selected State( 1 ), Color State( "red" )} )
)
)
);
Sheet Box(<<Hold(rpt), display box, ...)
説明
他のディスプレイボックスを縦または横に配置したディスプレイボックスを戻す。
次も参照
『スクリプトガイド』のH Sheet BoxとV Sheet Box
Sheet Panel Box(title, display box)
説明
シートボックスを縦にするか、横にするかを指定する。
Slider Box(minValue, maxValue, variable, script, <Set Width(n)>, <Rescale Slider(min, max)>)
説明
インタラクティブなスライダコントロールを作成する。
戻り値
ディスプレイボックス（スライダボックス）
必須の引数
minValue, maxValue
スライダの最小値および最大値となる数値。
variable
スライダボックスによって設定・変更される変数。
script
スライダボックスの移動に伴って実行される有効なJSLコマンド。
オプションの引数
Set Width(n)
スライダボックスの幅をピクセルで指定する。
Rescale Slider(minValue, maxValue)
スライダボックスの最大値と最小値をリセットする。
メモ
Set WidthとRescale Sliderをメッセージとしてスライダオブジェクトに送ることができます。例:
ex = .6;
New Window( "例", mybox = Slider Box( 0, 1, ex, Show( ex ) ) );
mybox << Set Width( 200 ) << Rescale Slider( 0, 5 );
次も参照
『スクリプトガイド』のSlider Box
Spacer Box(<Size(h, v)>, <Color(color)>)
説明
他のディスプレイボックスとの間のスペースを維持するため、または、LineUp Box内のセルを埋めるために使用されるディスプレイボックスを作成する。
戻り値
ディスプレイボックスへの参照
オプションの引数
Size(h, v)
h引数およびv引数で、ボックスのサイズをピクセル単位で指定する。
Color(color)
ボックスの色を、引数で指定されたJSLカラーに設定する。
次も参照
『スクリプトガイド』のSpacer Box
Spin Box(script)
説明
上向き/下向きの矢印ボタンを持つディスプレイボックスを戻す。
引数
script
クリックされた矢印の向きを示す引数と共に呼び出される。負の値は下向き、正の値は上向きを示します。1の値は1回のクリックを示し、2以上の値はクリックの反復を示します。
例
win = New Window( "例",
Lineup Box(
2,
nb = Number Edit Box( 3 ),
sb = Spin Box( Function( {value}, nb << Increment( value ) ) )
)
);
nb << Set Increment( 1 );
Splitter Box(<Size(x, y)>, display box, ...)
説明
他のディスプレイボックスを横または縦に配列できるディスプレイボックスと、そのサイズをインタラクティブに調整するためのコントロールを戻す。子のサイズは、分割線ボックス（splitter box）の幅または高さの割合で指定します。オプションのSize引数は、最上位の分割線ボックスに対する指定で、子ボックスはそれに対する割合での指定となります。
H Splitter Box()またはV Splitter Box()を使用します。
次も参照
『スクリプトガイド』のH Splitter BoxとV Splitter Box
String Col Box(title, {string, ...})
説明
テーブルボックス（Table Box）に列を作成し、引用符付きの文字列（string）の項目を保存する。引用符付きのtitleが列名になります。
String Col Edit Box(title, {string, ...})
説明
テーブルボックス（Table Box）に列を作成し、引用符付きの文字列（string）の項目を保存する。この関数によって作成された列の文字列は、編集できます。引用符付きのtitleが列名になります。
メモ
データを取得するには、次のメッセージを使用します。
data = obj << Get;
次も参照
『スクリプトガイド』のString Col Edit Box
Tab Box(Tab Page Box(Title(page title 1), <options>, contents of page 1), Tab Page Box(Title(page title 2), <options>, contents of page 2), ...);
説明
（Tab List Boxから名称変更。）タブ付きのウィンドウペインを作成する。引数には、タブページの名前とタブページの内容を交互に同数指定します。ページのタイトルは引用符で囲む必要があります。
引数
Tab Page Box
タブボックス（Tab Box）の中で使用できる、またはタイトルが付いた単独のコンテナとして使用できるディスプレイボックスを戻す。
– Title(page title #)は、1ページのタイトルを指定します。
– オプションには、<<Closeable(Boolean)（ボックスを閉じることができるかどうかを指定する）、<<Tip(string)（ツールチップを指定する引用符付き文字列）、<<Icon(string)（アイコンを指定する引用符付き文字列）があります。
– contents of page # は、タブのテキストを指定する引用符付き文字列。
例
New Window( "例",
Tab Box(
t1 = Tab Page Box( Title( "alpha" ), Panel Box( "panel", Text Box( "text" ) ) ),
t2 = Tab Page Box( Title( "beta" ), Popup Box( {"x", ex = 1, "y", ex = 2} ) ),
)
);
メモ
Tab Page Boxに送ることのできるメッセージの名称が、以下のように変更になりました。
– Set Titleの現在の名称はTitleです。
– Set Tipの現在の名称はTipです。
– Set Iconの現在の名称はIconです。
– Set Closeableの現在の名称はCloseableです。
次も参照
『スクリプトガイド』のTab BoxとTab Page Box
Tab List Box(title, tabExpr1, ...)
Tab Box(Tab Page Box(Title(page title 1), <options>, contents of page 1), Tab Page Box(Title(page title 2), <options>, contents of page 2), ...);を参照してください。
Tab Page Box(Title(string), <options>, contents)
説明
タブボックスの中で使用できる、またはタイトルが付いた単独のコンテナとして使用できるディスプレイボックスを戻す。
必須の引数
Title
タブのタイトルを指定する引用符付き文字列。
オプションのメッセージ
<<Tip(string)
ツールチップを指定する引用符付き文字列。
<<Closeable(Boolean)
ページを閉じることができるかどうかを指定する。
<<Icon(string)
アイコンを指定する引用符付き文字列。
<<Set Font(font name, <size>, <"bold"|"italic"|"underline"|strikeout">, <angle>
フォント属性を指定する。
<<Set Font Name("font name")
フォントの名前を指定する。
<<Set Font Scale(f)
フォントの倍率を指定する。倍率は、基本フォントとポイントサイズで決められたサイズに適用されます。
<<Set Font Size(n)
フォントサイズをピクセル数で指定する。
<<Set Font Style("plain"|"bold")
フォントスタイルを指定する。
メモ
Tab Page Boxに送ることのできるメッセージの名称が、以下のように変更になりました。
– Set Titleの現在の名称はTitleです。
– Set Tipの現在の名称はTipです。
– Set Iconの現在の名称はIconです。
– Set Closeableの現在の名称はCloseableです。
次も参照
『スクリプトガイド』のTab BoxとTab Page Box
Table Box(display box, ...)
説明
指定のディスプレイボックス（display box）を列としたレポートテーブル（表）を作成する。
Text Box(text, <arguments>)
説明
引用符付き文字列で指定されたテキスト（text）を含んだボックスを作成する。
引数
<<Justify Text(position)
引用符付き文字列で指定された位置（左“left”、中央“center”、または右“right”）にテキストを整列する。
<<Set Wrap(pixels)
テキストを折り返す位置を設定する。
次も参照
『スクリプトガイド』のText Box
Text Edit Box(text, <arguments>)
説明
引用符付き文字列（text）を含む編集ボックスを作成する。
引数
<<Password Style(Boolean)
パスワード入力用に、テキストを入力すると、アスタリスクを表示する。
<<Set Script
テキストが編集された後、指定のスクリプトを実行する。
<<Set Width(pixels)
テキストを折り返す位置を設定する。
次も参照
『スクリプトガイド』のText Edit Box
This Project()
説明
プロジェクトの中でJSLスクリプトが実行された場合に、そのプロジェクトを取得する。
例
次の例は、現在のプロジェクトのウィンドウタイトルを取得します。
project = New Project();
project << Save( "$DOCUMENTS/Test Project.jmpprj" );
project << Run Script(
New Window( "Project Title",
Text Box(This Project() << Get Window Title())
);
);
Tree Box(<{rootnodes}>, <Size(width, height)>, <MultiSelect(Boolean)>)
説明
ツリーノードで構成される階層構造のツリーを表示するボックスを作成する。
引数
{rootnodes}
ボックス内のTree Node()によって作成されるルートノードの名前を指定する。
Size(width, height)
ボックスの幅と高さを指定する（単位はピクセル）。
MultiSelect(Boolean)
ツリー内で複数のアイテムの選択を可能とする。
Tree Node(<data>)
説明
ツリーボックスディスプレイ内に表示するノードを作成する。Tree Nodeは、親と子の両方のノードに使用されます。
メモ
macOSの場合、子ノードを持つルートノードにCollapseメッセージを定義するSet Node Select Scriptを送ると、スクリプトが2回実行されます。Windowsの場合、スクリプトは実行されません。macOSで2回実行されるのは増分だけではありません。すべてのスクリプトが2回実行されます。ログへの出力、列の作成、何らかの削除など、すべての処理が2回行われます。
Triangulation(<dt>, X(col1, col1), <Y(col)>)
説明
与えられたデータ点に対してDelaunayの三角分割を行い、その結果のオブジェクトを戻す。データ点の座標に重複があった場合、それらのデータ点は一つにまとめられ、オプション指定のY値には平均が使われる。
例
tri = Triangulation(
X( [0 0 1 1], [0 1 0 1] ),
Y( [0 1 2 3] )
);
dt = Open( "$SAMPLE_DATA/Cities.jmp" );
tri = Triangulation( X( :X, :Y ), Y( :POP ) );
V Center Box(display box...)
引数で指定した子ディスプレイボックスを含むディスプレイボックスを戻す。子ディスプレイボックスを縦方向のスペースの中央に配置します。
V List Box(<Align("Center"|"Right")>, display box, ...)
説明
ディスプレイボックスを作成し、その中に別のディスプレイボックスを縦に並べて表示する。
引数
Align
ディスプレイボックスの位置を、右揃え（right）または中央揃え（center）に指定する。デフォルトでは、中央揃えで配置されます。
display box
リストボックスに含める任意の数のディスプレイボックスを指定する。
次も参照
『スクリプトガイド』のH List BoxとV List Box
V Scroll Box(<Size(v)>, display box)
説明
中身がスクロールボックスより大きい場合に右側と下側にスクロールバーがあるディスプレイボックスを戻す。
引数
Size(v)
スクロールバーの縦の長さ。
display box
スクロールボックスには任意の数のディスプレイボックスの引数を設定できる。
例
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "stretchable",
H Splitter Box(
Size( 400, 200 ),
Scroll Box(
Size( 200, 200 ),
dt <<Run Script( "Distribution" ),
<<Set Stretch( "Window", "Window" )
),
Scroll Box(
Size( 200, 200 ),
dt << Run Script( "二変量の関係(二変量) " ),
<<Set Stretch( "Window", "Window" )
),
<<Set Stretch( "Window", "Window" )
)
);
メモ
flexible引数は廃止されています。代わりに、Set Stretchを使用してください。
V Sheet Box(<<Hold(report), display box, ...)
説明
引数に指定された複数のディスプレイボックスを、縦方向に配置したディスプレイボックスを戻す。<<Hold()メッセージは、抜粋元となるレポートをどのシートが保持するかを示す。
次も参照
『スクリプトガイド』のH Sheet BoxとV Sheet Box
V Splitter Box(<Size(h,v)>, display box..., <arguments>)
説明
引数に指定された複数のディスプレイボックスを縦方向（パネル）に配置し、分割線で仕切ったディスプレイボックスを戻す。ユーザは分割線をドラッグしてパネルのサイズを変更できます。
引数
Size(v)
スクロールバーの縦の長さ。
display box
分割線ボックスには任意の数のディスプレイボックスの引数を設定できる。
オプションの引数
オプションの引数の詳細については、H Splitter Box(<Size(h, v)>, display box, ...)を参照してください。
次も参照
『スクリプトガイド』のH Splitter BoxとV Splitter Box
Web Browser Box(url)
説明
Webページを表示するディスプレイボックスを作成する。WindowsのInternet Explorerでのみ使用できます。
戻り値
Webブラウザボックスオブジェクトへの参照
引数
url
表示するWebページのURLを示す引用符付き文字列。
例
次の例では、分割線で仕切られたディスプレイボックスを作成し、左にWebブラウザボックスを、右にバブルプロットを配置します。
dt = Open( "$SAMPLE_DATA/PopAgeGroup.jmp" );
New Window( "例",
H Splitter Box(
Size( 800, 300 ),
wb = Web Browser Box( "http://www.jmp.com" ),
dt << Run Script( "バブルプロット 地域" )
)
);
wb << Set Stretch( "Window", "Window" ); // 自動的に縦横のサイズを調整する
wb << Set Max Size( 10000, 10000 ); // 最大サイズをピクセルで指定
メモ
targetが“_blank”である<a href>は、新しいInternet ExplorerウィンドウにWebページを開きます。targeが“_new”である<a href>は、アクティブなInternet ExplorerタブにWebページを開きます。
Window(<string|int>)
戻り値
開いているウィンドウすべてへの参照のリスト、または指定されたウィンドウへの参照
引数
string
開いている特定のウィンドウの名前を示す引用符付き文字列。
int
開いている特定のウィンドウを示す番号。
メモ
引数が指定されない場合は、開いているすべてのウィンドウのリストを戻します。
引数で指定されたウィンドウ名または数値が存在しない場合、空のリストを戻します。
Wrap List Box(display box, ...)
説明
複数のディスプレイボックスを横に並べて表示するリストボックスを作成する（ただし、印刷時には折り返して表示する）。
引数
display box
リストボックスに含める任意の数のディスプレイボックスを指定する。