データテーブル

dt<<Add Column Properties(property argument, ...)

選択されている列に指定のプロパティ（「値の表示順序」や「欠測値のコード」など）を追加する。

dt<<Add Multiple Columns(column prefix, n, <"Before First"|"After Last"|After(column)>, "Character"|"Numeric"|"Row State", <Field Width(n)>)

説明

データテーブル（dt）内の指定された位置にn個の列を追加する。

必須の引数

column prefix

新しい列の列名に追加する接頭辞。

n

追加する列の数。

Character

新しい列を文字タイプとする。

Numeric

新しい列を数値タイプとする。

Row State

新しい列を「行の属性」列とする。

オプションの引数

Before First

列を最初の列の前に追加する。

After Last

列を最後の列の後に追加する。

After(column)

列を指定の列の後に追加する。

Field Width(n)

列の桁数を指定する。

メモ

引数を省略した場合、または引数を正しく指定しなかった場合、「複数の列を追加」ウィンドウが表示されます。

次も参照

『スクリプトガイド』の一度に複数の列を追加

dt<<Add Rows(<n>, <"At Start"|"At End"|After(row number)>|{column name=value pairs})

説明

データテーブルの先頭、末尾、または指定した行の後ろに行を追加する。このメッセージでは、列名と値のペアを指定して、追加した行に値を設定することもできます。その場合、新しい行は、データテーブルの末尾に追加されます。

メモ

引数を省略した場合、または引数を正しく指定しなかった場合、「行の追加」ウィンドウが表示されます。

次も参照

『スクリプトガイド』の行の追加

dt<<Add Scripts to Table(script, ...)

dt<<Add Properties to Table(script, ...)

スクリプト（script）をデータテーブルに追加する。

dt<<Anonymize(<Columns(column list(s))>, <Output Table Name(name)>);

データ、一部の列プロパティ、およびテーブルスクリプトから識別可能な値を削除する。データテーブルまたは指定の列のリストに適用されます。新しいデータテーブルには、引用符付きのname引数で指定された名前が付きます。

dt<<Begin Data Update

データテーブルのセルをすばやく更新できるように、表示の更新をオフにする。表示の更新をオンに戻すには、End Data Updateを使います。

メモ

Begin Data Updateは、データ値を変更する以外のテーブル操作によるデータの再描画には影響しません。たとえば、列を削除または追加する場合は、データテーブルが更新された後、データ値の更新が開始されます。

dt<<Clear Column Selection

選択されているすべての列の選択を解除する。

dt<<Clear Edit Lock(<"Modify Cells">, <"Add Rows">, <"Add Columns">, <"Delete Rows">, <"Delete Columns">)

説明

データテーブルに対して、指定された操作を再び行えるようにする。

メモ

引数を指定しなかった場合、すべてのロックが解除されます。

dt<<Clear Row States

有効な行の属性をすべてクリアする。

dt<<Clear Select

現在の選択をクリアする。

dt<<Clone Formula Column(column, n, Substitute Column Reference(column1, {list}))

n個の新しい計算式列を作成し、column1への参照をlistの列に置き換えて元のcolumnの計算式に挿入する。

dt<<Close Data Grid(Boolean)

真の場合にデータテーブルグリッドを閉じる。

dt<<Close Side Panels(Boolean)

真の場合にデータテーブルのサイドパネルを閉じる。

dt<<Color or Mark by Column(column, <named arguments>)

dt<<Color by Column(column, <named arguments>)

dt<<Marker By Column(column, <named arguments> );

説明

データテーブルの列の値に従って色またはマーカーを割り当てる。オプションの引数が指定されていない場合は、デフォルトのカラーテーマに従って色が割り当てられます。

必須の引数

column

色またはマーカーを付ける列。

オプションの名前付き引数

Color(n)

指定のJMPカラーを使用する。

Add Marker(Boolean)

データテーブル内のマーカーの表示/非表示を切り替える。

Color Theme(color theme)

引用符付きで指定されたカラーテーマを使用する。

Marker Theme(marker theme)

引用符付きで指定されたマーカーテーマを使用する。指定できるテーマは、"Standard"（標準）、"Hollow"（中抜き）、"Paired"（ペア）、"Classic"（クラシック）、および、"Alphanumeric"（英数字）。

Continuous Scale|Continuous Scale(Boolean)

指定の列の値に従って、グラデーションになった色を割り当てる。

Reverse Scale|Reverse

使用中の色を反転する。

Excluded Rows(Boolean)

真の場合は、除外されている列に行の属性を適用する。

"Make Window with Legend"

凡例のウィンドウを別に作成する。

dt<<Color Rows by Row State

行の属性による色の割り当てに基づき、データテーブルグリッド内の行に色をつける。行の色を無効にするには、再度このメッセージを送ります。

dt<<Combine Columns(Delimiter("delim"), Columns(column1, column2, etc.), Column Name(quoted string))

複数の列の値を1つに結合する。元の列の値は、引用符付きのdelim引数で指定された区切り文字で区切られます。

例

dt = Open( "$SAMPLE_DATA/Consumer Preferences.jmp" );

dt << Combine Columns(

	Delimiter( "," ),

	Columns(

		: 起床後に歯磨き,

		: 食後に歯磨き,

		: 就寝前に歯磨き,

		: 別のタイミングで歯磨き

	),

	Column Name( "いつ歯磨きをするか" )

);

dt<<Compress File When Saved(Boolean)

データテーブルの保存時にファイルを圧縮する。

dt<<Compress Selected Columns({column1, ...})

リストされた列を可能な限り小さく圧縮する。文字データの列の場合、水準が255個未満であれば1バイトに圧縮できます。数字データの列の場合、数値が-127～127の整数であれば1バイトに圧縮できます。

dt<<Concatenate(dt2|Data Table(name)|Multiple Data Table(name) arguments, (<"Private"|"Invisible">), <Output Table Name(name)>|"Append to First Table">, <"Keep Formulas">, <"Create Source Column">)

説明

データテーブル（dt）とデータテーブル2（dt2）を連結し、新しいデータテーブル（name）を作成する。デフォルトでは、Concatenateは新しいデータテーブルを作成し、指定された各データテーブルの行を追加します。

戻り値

連結されたデータテーブルへの参照

必須の引数

dt2|Data Table(name)|Multiple Data Table(name)

結合したいデータテーブルのデータテーブル参照または名前。

オプションの引数

"Private"

データテーブルウィンドウには表示せずにデータテーブルを開く引用符付きキーワード。

"Invisible"

出力のデータテーブルを非表示にする引用符付きキーワード。データテーブルを非表示で出力して、後に続くスクリプトで利用する場合、この引数を使用してください。このデータテーブルは、ホームウィンドウの「ウィンドウリスト」または［ウィンドウ］>［再表示］のリストに表示されます。

Output Table name(name)

最終的なデータテーブルの名前。名前を入力しない場合、データテーブルには「無題#」（たとえば、「無題1」）という名前が付きます。

"Append to First Table"

最初の引数にある最初のデータテーブル参照またはデータテーブル名に行を追加する。このオプションは、新しいデータテーブルを作成する代わりとなるものです。

"Keep Formulas"

最終的なデータテーブルに計算式を含める。

"Create Source Column"

新しいデータテーブルに元のテーブルという列を追加する。

メモ

"Private"と"Invisible"は、"Append to First Table"を使用していない場合のみ適用されます。

次も参照

『スクリプトガイド』のデータテーブルを縦方向に連結する

dt<<Copy Column Properties

選択されているすべての列の列プロパティをコピーする。データテーブルで列を選択しておく代わりに、リストで列を指定することもできます。

例

dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );

dt << Select Columns( :MODULUS, :ELONG );

dt << Copy Column Properties;

New Window( "Script", Script Box( "//ここに貼り付けてください。" ) );

または

dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );

dt << Copy Column Properties( {:MODULUS, :ELONG} );

New Window( "Script", Script Box( "//ここに貼り付けてください。" ) );

dt<<Copy Selected Properties

説明

選択されているテーブルプロパティをクリップボードにコピーする。

例

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << Select Properties( {"一変量の分布", "二変量の関係(一元配置)"} );

proplist = dt << Copy Selected Properties();

New Window( "Script", Script Box( "//ここに貼り付けてください。" ) );

dt<<Copy Table Script("No Data")

データテーブルを再作成するためのスクリプトを、クリップボードにコピーする。"No Data"という引数を指定すると、スクリプトからデータ部分が省かれます。

dt<<Copy Table Scripts

dt<<Copy Selected Properties

説明

選択されているスクリプトをクリップボードにコピーする。

例

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << Select Properties( {"一変量の分布", "二変量の関係(一元配置)"} );

proplist = dt << Copy Table Scripts();

New Window( "Script", Script Box( "//ここに貼り付けてください。" ) );

dt<<Data Filter(<Location(x, y), <"Close Outline">, <"Local">, <Inverse(Boolean)>, <Show Columns Selector(Boolean)>, <Title(quoted string)>, <Save and Restore Current Row States(Boolean)>, <Conditional(Boolean)>, <Auto Clear(Boolean)>, <Group By AND(Boolean)>, <Show Histograms and Bars(Boolean)>, <Count Excluded Rows(Boolean)>, <Mode(...)>, <Add Filter((cols(...), <Where(...)>, <Display(...)>, <Select Missing(cols)>, <Order By Count(cols)>)>, <Favorites(...)>, <Animation(...)>)

データフィルタを作成する。引数が指定されていない場合は、「フィルタ列の追加」ウィンドウが表示されます。

オプションの引数

Location(x, y)

データフィルタウィンドウを指定の場所に移動する。xとyはピクセル単位で指定します。0,0はディスプレイの左上隅を意味します。

"Close Outline"

データフィルタアウトラインを閉じる。

"Local"

レポートにフィルタを組み込み、他のレポートに影響を及ぼさずに1つまたは複数のプラットフォームをフィルタできるようにする。

Inverse(Boolean)

すべてのフィルタに対し、指定の行を除くすべての行を選択する。

Show Columns Selector(Boolean)

真の場合は、フィルタに新しい列を追加するための列名リストを表示する。

Title(quoted string)

アウトラインに表示するタイトル。

Save and Restore Current Row States(Boolean)

「データフィルタ」ウィンドウを閉じるときに現在の行の属性を復元する。

Conditional(Boolean)

選択されているフィルタ列に対し、表示されるカテゴリを制限する。

Auto Clear(Boolean)

「データフィルタ」で複数の名義尺度または順序尺度の列が選択されている場合、フィルタ基準を1つ選択する前に、前回選択した基準を選択解除する。

Group By AND(Boolean)

デフォルトでは、フィルタグループを作成した場合、ORによって、1つまたは複数のフィルタが追加され、2つ目のフィルタグループが作成されます。Grouped By ANDを指定した場合は、動作が逆になり、ANDでグループ化されます。

Show Histograms and Bars(Boolean)

データフィルタのヒストグラムと棒の表示/非表示を切り替える。

Count Excluded Rows(Boolean)

除外された行の数の表示/非表示を切り替える。

Mode

フィルタには、次の3つのモードがあります。Select(Boolean)は、データテーブル内で選択された行を強調表示（または非表示）します。Show(Boolean)は、選択されていない行を表示または含め、［非表示］アイコンを表示します。Include(Boolean)は、選択されていない行を表示または含め、［除外］アイコンを表示します。

グローバルデータフィルタのデフォルトは、Select()、Show(0)、Include(0)です。ローカルデータフィルタのデフォルトは、Show(1)、Include(1)で、Select()は有効なオプションではありません。

Add Filter

データフィルタを作成する。引数には、Columns()、Where()、Display()、Select Missing(cols)、Order By Count(cols)があります。Columns()は、カンマで区切った1つまたは複数の列名をとります。フィルタを定義する場合は、1つまたは複数のWhere節を追加します。

Where

データのフィルタリングに使うWhere節を定義する。

Display(column, size, display type)

指定のカテゴリカル列の水準を、どのようにフィルタに表示するかを設定する。引数は、Blocks Display、List Display、Single Category Display、Check Box Display、Radio Box Display。カテゴリカルな列では、Find(Set Text(quoted string))引数を使って検索フィールドを含め、初期化することができます。連続尺度の列では、Displayを使い、size引数を含めることもできます。

Select Missing Cols(cols)

連続尺度の列で欠測値を選択する。

Order by Count(cols)

このオプションは、カテゴリカルな列に対し、度数の降順に従って値を並べる。

Favorites

現在のデータフィルタの条件をお気に入りとして保存する。

Animation

指定されたアニメーションの向きで、行の選択と選択解除を交互に繰り返す。オプションの引数には、Animate Column(col)、Animate Rate(number)、"Forward"|"Backward"|"Bounce"があり、"Forward"|"Backward"|"Bounce"はアニメーションの向きを、最初から最後へと前進させます。"Backward"は、アニメーションの向きを、最後から最初へと後進させます。"Bounce"は、アニメーションの向きを、前進させた後、後進させます。

次も参照

『スクリプトガイド』のデータフィルタの追加

『JMPの使用法』のデータフィルタ

dt<<Get Header Height

列見出しの高さを戻す（単位はピクセル）。

dt<<Data View(<named arguments>)

説明

新しいウィンドウにデータテーブルを複製する。次の引用符付き引数のいずれか1つを指定した場合は、該当する行だけが新しいデータテーブルに含まれます。

戻り値

データビューへの参照

オプションの名前付き引数

Excluded

新しいデータテーブルに、元のデータテーブルで除外されている行だけが含まれる。

Labeled|Labelled

新しいデータテーブルに、元のデータテーブルでラベルありとマークされている行だけが含まれる。

Hidden

新しいデータテーブルに、元のデータテーブルで表示しないとマークされている行だけが含まれる。

Selected

新しいデータテーブルに、元のデータテーブルで選択されている行だけが含まれる。

dt<<Delete Columns(column1, column2, ...)

dt<<Delete Column

説明

データテーブルdtから1つまたは複数の列を削除する。colには、削除する列を指定します。引数がない場合、選択されている列があれば、それを削除します。

次も参照

『スクリプトガイド』の列の削除

dt<<Delete Rows(<n>)

dt<<Delete Rows({n, o, p, ...})

dt<<Delete Rows({n::q})

dt<<Delete Rows([n, o, p])

dt<<Delete Row(preceding arguments)

説明

現在選択されている行、または指定された行を削除する。削除された行の行数を戻します。

次も参照

『スクリプトガイド』の行の削除

dt<<Delete Scripts(table script name|{table script1, table script2, ...})

説明

引用符付きの名前で指定されたデータテーブルスクリプト、もしくはリストで指定された複数のデータテーブルスクリプトを削除する。

メモ

14より以前のバージョンのJMPでテーブルスクリプトを削除するには、Delete Table Propertyを使用してください。

dt<<Delete Table Property(name|{property1, property2, ...})

引用符付きのnameで指定されたテーブルプロパティ（スクリプトや変数など）を削除する。

dt<<Delete Table Variable(name)

引用符付きのnameで指定されたテーブル変数を削除する。

dt<<Disable Undo(Boolean)

真の場合にデータテーブル内で「元に戻す」または「取り消し」操作を無効にする。

dt<<End Data Update

Begin Data Updateメッセージの後で、表示の更新を再開する。これらのコマンドは、変更箇所が多数ある場合に、データテーブルをすばやく更新するために使われます。表示の更新をオフにすると更新速度が上がります。

dt<<Exclude

dt<<Unexclude

データテーブル（dt）内で選択された行を「除外する」から「除外しない」、またはその逆に切り替える。

dt<<Get All Columns As Matrix

データテーブル（dt）のすべての列の値を行列で戻す。文字型の列には、水準に従って1から順に番号が付けられます。

dt<<Get As Matrix(<{list of columns by name}>|<{list of columns by number}>, <column range>)

データテーブル（dt）の数値列の値を行列で戻す。デフォルトでは、すべての数値列が出力されます。

例

dt1 = Open( "$SAMPLE_DATA/Big Class.jmp" );

cols = dt1 << Get As Matrix(); // すべての数値列を戻す

Show( cols );

cols =

[ 12 59 95,

12 61 123,

12 55 74,...]

colnums = dt1 << Get As Matrix( {4, 5} ); // 4列目と5列目を戻す

Show( colnums );

colnums = [ 59 95, 61 123, 55 74, 66 145, 52 64, 60 84, 61 128, ...]

dt2 = Open( "$SAMPLE_DATA/Probe.jmp" );

colrange = dt2 << Get As Matrix( 10::22); // 10~22列目を戻す

Show( colrange );

colrange =

[ -0.08818069845438 0.711340010166168 1.85904002189636 0.396923005580902 4.50656986236572 7.86504983901978 1.53891003131866 -2.76178002357483 0.0711032971739769 5.75577020645142 -3.62023997306824 -0.971698999404907 -0.0525696985423565, ...]

dt<<Get As Report

データテーブルをレポートにして戻す。データテーブルで行および列が選択されている場合は、選択されている行および列のみがレポートに含まれます。

例

次のスクリプトは、Big Class.jmpをレポートにして、分布とともに1つのウィンドウ内に表示します。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dtRpt = dt << Get As Report;

distRpt = V List Box(

	dt << Distribution(

		Continuous Distribution( Column( :"体重(ポンド)"n ) ),

		Nominal Distribution( Column( :年齢 ) )

	)

);

New Window( "例", H List Box( dtRpt, distRpt ) );

dt<<Get Cell Height

データテーブルのセルの高さ（ピクセル）を戻す。

dt<<Get Column Names(quoted string, <modeling type>, <data type>)

説明

データテーブルの列名をリストにして戻す。引用符付き"String"と指定されている場合、列の参照リストではなく、引用符付き文字列のリストを戻します。

必須の引数

quoted string

列の参照リストではなく、引用符付き文字列のリストを戻します。

オプションの引数

modeling type

引用符を付けて尺度を指定する。オプションには、"Continuous"（連続尺度）、"Ordinal"（順序尺度）、"Nominal"（名義尺度）、"Multiple Response"（多重応答）、"Unstructured Text"（非構造化テキスト）、"None"（なし）、"Vector"（ベクトル）があります。

data type

引用符を付けてデータタイプを指定する。オプションには、"Numeric"（数値）、"Character"（文字）、"Row State"（行の属性）、"Expression"（式）があります。

メモ

データタイプや尺度を指定すると、該当する列の値のみが取得されます。データタイプや尺度は複数指定できます。

次も参照

『スクリプトガイド』の列名の取得

dt<<Get Column Reference({list of column names}|[matrix of column numbers])

dt<<Get Column References({list of column names}|[matrix of column numbers])

リスト内で指定された引用符付き列名または行列内で指定された番号の、列に対する参照を戻す。リストまたは行列を使用しない場合、すべての列への参照のリストが戻されます。

dt<<Get Display Width

列の表示幅（単位はピクセル）を戻す。

dt<<Get Edit Lock

データテーブルで許可されていない操作（セルの編集、行の追加・削除、列の追加・削除など）を戻す。

dt<<Get Excluded Columns

データテーブルで現在除外されている列を戻す。

dt<<Get Excluded Rows

データテーブルで現在除外されている行を戻す。

dt<<Get Hidden Columns

データテーブルで現在非表示の列を戻す。

dt<<Get Hidden Rows

データテーブルで現在非表示の行を戻す。

dt<<Get Journal

ディスプレイボックスのジャーナルを生成するソースを引用符付き文字列として戻す。

例

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

biv = dt << Bivariate( Y(:"体重(ポンド)"n ), X(:"身長(インチ)"n ) );

rbiv = biv << Report;

Print( rbiv << Get Journal );

dt<<Get Label Columns

dt<<Get Labeled Columns

dt<<Get Labelled Columns

データテーブルで現在ラベルのついている列を戻す。

例

「PopAgeGroup.jmp」では、「国」列と「年」列にラベルがついています。次のスクリプトは、ラベルのついた列の名前のリストを戻します。

dt = Open( "$SAMPLE_DATA/PopAgeGroup.jmp" );

dt << Get Labeled Columns;

{:Country, :Year}

dt<<Get Labeled Rows

dt<<Get Labelled Rows

データテーブルで現在ラベルのついている行を戻す。

dt<<Get Name

データテーブルの名前を戻す。

dt<<Get Path

JMPのデータテーブルの絶対パスを戻す。読み込んだ後にまだ保存していないデータの場合は、絶対パスは戻されません。

dt<<Get Property(name)

引用符付きプロパティnameのスクリプトを戻す。

dt<<Get Row Change Function

行が選択されたときに評価する式を戻す。

dt<<Get Row ID Width

行番号の領域の表示幅（単位はピクセル）を戻す。

dt<<Get Row States

データテーブルまたはデータフィルタの各行の行属性を含むベクトルを戻す。

dt<<Get Rows Where(where clause)

指定のWhere条件とマッチするデータテーブルの行を戻す。以下はその例です。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << Get Rows Where( :性別 == "M" );

dt << Get Rows Where( :性別 == "M" & :年齢 < 15 );

dt<<Get Script(<script name>)

引用符付きのscript nameで指定されたスクリプトを戻す。script nameが省略された場合、Get Scriptは、データテーブルを表すテキストを、データテーブルに保存されているすべてのスクリプトとともに戻します。

dt<<Get Script Group(<group name>)

説明

引用符付きのgroup nameに含まれているテーブルスクリプトのスクリプト名を、リストで戻す。グループ名が指定されていない場合は、すべてのグループのすべてのテーブルスクリプトのリストを戻します。

次も参照

『スクリプトガイド』のグループとグループ名の取得

dt<<Get Script Group Names

説明

複数のテーブルスクリプトグループのグループ名を、リストで戻す。

次も参照

『スクリプトガイド』のグループとグループ名の取得

dt<<Get Scroll Locked Columns

スクロールロックされている列のリストを戻す。

dt<<Get Selected Columns(<quoted string>)

説明

選択されている列のリストを列参照として戻す。選択されている列の名前を文字列のリストとして戻すには、引用符付きのstring引数を指定してください。

次も参照

『スクリプトガイド』の選択されている列の取得

dt<<Get Selected Properties(<{list of properties}>)

説明

選択されているテーブルプロパティをリストで戻す。

オプションの引数

list of properties

取得するプロパティを指定する。

例

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << Select Properties( {2, 4} );

proplist = dt << Get Selected Properties();

// 2番目と4番目のテーブルスクリプトを選択し、

// それらのスクリプトを戻す

dt<<Get Selected Rows()

選択されている行を戻す。

dt<<Get Table Script Names()

データテーブルのすべてのスクリプト名およびプロパティ名のリストを戻す。

dt<<Get Table Variable(name)

引用符付きのnameで指定された変数の値を戻す。

dt<<Get Table Variable Names

すべてのテーブル変数の変数名を、リストで戻す。

dt<<Go To Row(n)

データテーブル（dt）の番号nの行を選択する。

dt<<Group Columns({column1, column2, ...})

dt<<Group Columns(group name, column, n)

dt<<Group Columns(first column, n)

説明

列を、引用符付きのgroup nameで指定されたグループ名でグループ化する。グループ化する列をリストの形で指定するか、最初の列の名前と列数という形で指定します。後者の場合、数字nは、その列とそれに続くn-1個の列をグループ化することを意味します。

次も参照

『スクリプトガイド』の列のグループ化

dt<<Group Scripts({script1, script2, ...})

説明

引数のリストで指定されたテーブルスクリプトをグループ化する。

次も参照

『スクリプトガイド』のテーブルスクリプトのグループを扱う

dt<<Hide

dt<<Unhide

データテーブル（dt）内で選択された行を「表示しない」から「表示する」、またはその逆に切り替える。

dt<<Hide and Exclude

選択されている行を非表示かつ除外にする。

dt<<Invert Column Selection(<{list of columns}>)

説明

現在選択されていない列を選択し、選択されている列の選択を解除する。list of columnsが指定されている場合、リストにない列が選択されます。

次も参照

『スクリプトガイド』の列の選択の逆転

dt<<Invert Row Selection

現在選択されていない行を選択し、選択されている行の選択を解除する。

dt<<Is Dirty

テーブルが保存された状態から変更されている場合は1、それ以外は0を戻す。

dt<<Join(With(Data Table(name)), (<"Private">|<"Invisible">), Select(columns), Select With(columns), (By Matching Columns(column1=column2, ...)|"Cartesian"|"By Row Number"), <"Merge Same Name Columns">, <"Match Flag">, <Copy Formula(Boolean)>, <Suppress Formula Evaluation(Boolean)>, <"Update">, <Drop Multiples(Boolean, Boolean)>, <Include Non Matches(Boolean, Boolean)>, <"Preserve Main Table Order">, <Output Table Name(name))>

説明

データテーブル（dtおよびData Table）を横に並べて結合する。

戻り値

データテーブル

必須の引数

With(Data Table(name))

アクティブなデータテーブルと結合するデータテーブルを指定する。

"Private"

データテーブルウィンドウには表示せずにデータテーブルを開く引用符付きキーワードを指定する。

"Invisible"

出力のデータテーブルを非表示にする引用符付きキーワードを指定する。データテーブルを非表示で出力して、後に続くスクリプトで利用する場合、この引数を使用してください。このデータテーブルは、ホームウィンドウの「ウィンドウリスト」または［ウィンドウ］>［再表示］のリストに表示されます。

Select(columns)

アクティブなデータテーブルと結合するデータテーブルを選択する。

Select With(columns)

By Matching Columns(column1=column2)

両方のテーブルで値とデータタイプがマッチする列を選択する。

"Cartesian"

直積で結合すると、2つの元のデータテーブルの行の可能な組合せがすべて含まれた新しいデータテーブルが作成されます。最初のテーブルのデータを2番目のテーブルのデータと組み合わせて、値のすべての組合せがセットで表示されます。

"By Row Number"

2つのテーブルを横に結合します。

"Merge Same Name Columns"

2つ目のテーブルの列データで、元のテーブルにある同じ名前の列のデータが置き換えられます。最初のテーブルの欠測値は、2番目のテーブルの非欠測値で置き換えられます。

"Match Flag"

対応する列の値で結合する場合に、「対応フラグ」列を作成するかどうかを指定します。

Copy Formula(Boolean)

主テーブルまたは結合するテーブルの計算式を出力列に含めます。

Suppress Formula Evaluation(Boolean)

新しいテーブルの作成中に、列の計算式を再評価しない。

"Update"

2つ目のテーブルの列データで、元のテーブルにある同じ名前の列のデータが変更されます。更新された結果は、出力先の新しいデータテーブルに表示されます。次の点に注意してください。データは、欠測値では置き換えられません。また、出力テーブルは、元のテーブルと同じ列を持ちます。そのため、"Update"を使用するときは、列を選択してください。"Update"オプションは、行番号で結合する場合、または対応する列の値で結合する場合のみ使用できます。

Drop Multiples(Boolean, Boolean)

新しいデータテーブルに名前ごとに1行だけ含まれるよう指定する。対応する列の値で結合する場合のみ適用されます。

Include Non Matches(Boolean, Boolean)

主データテーブルと新しいデータテーブルで対応しない列を含める。対応する列の値で結合する場合のみ適用されます。

"Preserve Main Table Order"

対応する列を基準に並べ替えるのではなく、主テーブルの順序を結合後のテーブルでも維持する。

Output Table Name(name)

結合後のテーブルの名前を指定します。名前を指定しない場合、データテーブルには「無題#」（たとえば、「無題1」）という名前が付きます。

次も参照

『JMPの使用法』のデータテーブルの結合

dt<<Journal

データテーブルからジャーナルを作成する。データグリッドのみが含まれ、ノート、変数、またはスクリプトは含まれません。

メモ

– JMP 14以降で作成されたジャーナルは大きな行列を圧縮した行列データを含んでいる場合があります。ジャーナルを開いてそこからデータを抽出するJSLスクリプトを使用するときは、Journalメッセージでジャーナルをディスクに保存するのではなく、（行列を圧縮しない）Get Journalメッセージの使用を検討してください。

次も参照

dt<<Get Journalを参照してください。

『スクリプトガイド』のジャーナルの作成

dt<<Journal Link(<Save(<path>)|Embed()>, <Button Name(<name>)>))

現在のジャーナルに、データテーブルへのリンクを追加する。ジャーナルが存在しない場合は、新しいジャーナルが作成されます。

オプションの引数

path

テーブルの保存場所を引用符付きのpathで指定する。データテーブルがすでにディスク上に保存されている場合は、この指定を省くことができます。保存されていない状態で指定を省くと、ジャーナルリンクが不完全になり、テーブルの再ロードができなくなります。

Embed

データテーブルを再作成するJSLスクリプトを組み込む。

Button Name(name)

ボタンに表示される名前。name引数は引用符付きです。ボタン名を指定しなかった場合、データテーブルの名前が使用されます。

dt<<Label

dt<<Unlabel

データテーブル（dt）内の選択された行を「ラベルあり」から「ラベルなし」、またはその逆に切り替える。

dt<<Last Modified

データテーブルが最後に保存された日付を戻す。

dt<<Layout

Layoutは将来のリリースで削除される予定です。代わりにJournalを使用してください。

dt<<Lock Data Table

説明

データテーブルをロックして、データや列プロパティが追加または変更されないようにする。

次も参照

dt <<Set Edit Lock(<"Modify Cells">, <"Add Rows">, <"Add Columns">, <"Delete Rows">, <"Delete Columns">)

dt<<Make Indicator Columns(<Append Column Name(Boolean)>, <Include Missing(Boolean)>)

指定したカテゴリカル列について、0または1の値をとる指示変数の列を作成する。

例

次の例では、「性別」列の指示変数列を作成します。Append Column Nameを指定すると、作成される列名は「性別_F」と「性別_M」になります。指定しない場合は、水準値が列名となります（「F」と「M」）。Include Missingは、欠測値を含めます。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << Make Indicator Columns(

	Columns( :性別 ),

	Append Column Name( 1 ),

	Include Missing( 1 )

);

dt<<Make RowState Handler

行の属性ハンドラの関数を作成する。関数の引数には、行の属性が変更された行をとる。

dt<<Make SAS Data Step

データテーブルと同じデータを作成するためのSASデータステップを生成する。

dt<<Make SAS Data Step Window

データテーブルと同じデータを作成するためのSASデータステップを生成し、それをSASスクリプトウィンドウに表示する。

dt<<Make Validation Column

データを学習セットと検証セットに分けるための列を作成する。

dt<<Marker by Column(column)

説明

指定されたデータテーブルの列columnの値に従ってマーカーを割り当てる。

次も参照

dt<<Marker By Column(column, <named arguments> );

dt<<Markers(n)

選択されている行にマーカー番号nのマーカーを割り当てる。

dt<<Maximize Display

このメッセージは廃止されます。代わりにOptimize Displayを使用してください。

すべての列のサイズを再調整して、データテーブルのウィンドウを最適なサイズに拡大する。

dt<<Move Script Group(group name, "To First"|"To Last"|After(table script name)|After(group))

説明

引用符付きのgroup nameで指定されたテーブルスクリプトグループを並べ替える。

次も参照

『スクリプトガイド』のスクリプトグループの移動

dt<<Move Selected Column(name(s), "To First"|"To Last"|After(name))

dt<<Move Selected Columns(name(s), "To First"|"To Last"|After(name))

説明

データテーブル内で選択されている列を、指定した位置に移動する。name引数は引用符付きです。

例

次の例は、「Big Class.jmp」データテーブルの「年齢」列を全列の最後へと移動させます。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << Go To( :年齢 );

dt << Move Selected Columns( "To Last" );

リストを使って列名を指定することもできます。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

list = {"名前", "性別"};

dt << Move Selected Columns( list, "To Last" );

dt<<Move Rows("At Start"|"At End"|After(n))

データテーブル内で選択されている行を、指定した位置に移動する。nは行番号を表します。

dt<<New Column(name, <data type>, <modeling type>, <Format(format, width)>, <Formula()>, <Set Values({..., ..., })>, <Set Property(properties)>)

説明

データテーブル（dt）の最後に、引用符付きで指定された名前（"name"）の新しい列を追加する。特に指定しない限り、列の値は連続量の数値で、列幅は12文字です。

戻り値

列への参照

必須の引数

name

新しい列の名前。

オプションの引数

data type

データタイプを指定する引用符付き文字列。オプションには、"Numeric"（数値）、"Character"（文字）、"Row State"（行の属性）、"Expression"（式）があります。

modeling type

尺度を指定する引用符付き文字列（"Continuous"（連続尺度）、"Nominal"（名義尺度）、"Ordinal"（順序尺度）、"Multiple Response"（多重応答）、"Unstructured Text"（非構造化テキスト）、"None"（なし）、"Vector"（ベクトル））。

Format(format, width)

表示形式と列の幅を設定する。

Set Values({})

列のデータ値を指定する。

Formula

列の計算式を指定する。

Set Property(properties)

データテーブル列でサポートされるメッセージを指定する。「列の新規作成」ウィンドウの［列プロパティ］プロパティのリストを確認できます。AxisとLink Referenceは、プロパティです。

次も参照

数値の表示形式を設定する例については、col<<Format(<width>, <decimal places>, <"Use Thousands Separator">)を参照してください。

『スクリプトガイド』の列の作成

『JMPの使用法』のデータタイプ、尺度、数値の表示形式に関するオプション、JMPの列プロパティ

dt<<New Data Box()

ディスプレイボックスツリーに、データテーブルビューを作成する。データテーブルとレポートを1つのウィンドウに表示するのに便利です。データテーブルオブジェクトにNew Data Boxメッセージを送ると、データブラウザボックスが作成されます。

例

次のスクリプトは、データテーブルビューとレポートを作成し、1つのウィンドウに表示します。データテーブルは、データブラウザボックスに配置されます。ボックスの幅は、800ピクセルに設定されます。自動伸縮をオフにしているため、ウィンドウの右端を伸ばしても、データテーブルビューの幅は800ピクセルに保たれます。

dtA = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp", invisible );

nw = New Window( "例",

	H List Box(

		V List Box( dtbox = dtA << New Data Box() ),

		dtA << Distribution(

			Continuous Distribution( Column( :NPN1 ) ),

			Continuous Distribution( Column( :PNP1 ) )

		)

	)

);

dtbox << Set Stretch( "Off", "Off" ) << Set Width( 800 );

dt<<New Data View

データテーブルの複製を開く。2番目のデータテーブルは元のデータテーブルと同一で、元のデータテーブルにリンクしています。そのため、どちらか一方が変更されると、他方にも反映されます。また、どちらか一方を閉じると他方も閉じられ、データテーブルへの参照はすべて削除されます。

これは、非表示のデータテーブルを表示する際に便利です。

dt<<New Script(name, script)

dt<<Set Property(name, script)

scriptで指定されたスクリプトを保存する新しいテーブルプロパティ（「テーブルスクリプト」ともいう）を、引用符付きのnameを使って作成する。

今後サポートされなくなるNew Property()およびNew Table Property()の代わりにNew Script()またはSet Property()を使用してください。

例

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << Set Property( "二変量の例", Bivariate(Y(:"体重(ポンド)"n), X(:"身長(インチ)"n), Fit Line ) );

dt<<New Table Variable(name, number)

dt<<Set Table Variable(name, number)

引用符付きのnameとnumberを使って新しいテーブル変数を作成する。

dt<<Next Selected

次の選択行を表示する。次の選択行が画面の外にある場合は、データテーブルを下にスクロールします。

dt<<Optimize Display

すべての列のサイズを再調整して、データテーブルのウィンドウを最適なサイズに拡大する。

dt<<Original Order

データテーブル（dt）の列の順を保存されている順序に戻す。

dt<<Paste Column Properties

複数の列プロパティの情報を含むリストを、複数の列に貼り付ける。データテーブルで対象の列を選択しておく代わりに、列のリストを指定することもできます。

例

dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );

dt << Copy Column Properties( {:引張応力, :伸び} );

dt2 = New Table( "テスト",

	New Column( "T1", numeric, continuous ),

	New Column( "T2", numeric, continuous ),

	New Column( "T3", numeric, continuous ),

	Add Rows( 10 )

);

dt2 << Paste Column Properties( {:T1, :T3} );

//引張応力と伸びの列プロパティをT1とT3に貼り付ける

dt<<Predictor Screening

dt<<Screen Predictors

説明

効果が大きい説明変数を特定するのに使用される。

例

dt = Open( "$SAMPLE_DATA/Boston Housing.jmp" );

obj = dt << Predictor Screening(

	Y( :持ち家の価格),

	X( :犯罪率, :産業, : 川, :窒素酸化物, :部屋数, :築年, :ビジネス地域への距離, :高速道路)

);

dt<<Previous Selected

前の選択行を表示する。前の選択行が画面の外にある場合は、データテーブルを上にスクロールします。

dt<<Print Window(<"Show Dialog">)

ウィンドウを印刷する。オプションの名前付き引数"Show Dialog"が指定されている場合は、印刷ウィンドウが表示されます。そうでない場合は、ウィンドウはデフォルトのプリンタに現在の設定を使って印刷され、印刷ウィンドウは表示されません。

dt<<Rename Script Group(old name, new name)

説明

テーブルスクリプトグループのグループ名を変更する。

例

dt << Rename Script Group( "地図", "ストリートマップ" );

dt<<Reorder By Data Type

データテーブル（dt）の列を、データタイプによって行の属性、文字、数値の順に並べ替える。

dt<<Reorder By Modeling Type

データテーブル（dt）の列を、尺度によって連続尺度、順序尺度、名義尺度の順に並べ替える。

dt<<Reorder By Name

データテーブル（dt）の列を名前の昇順に並べ替える。

dt<<Rerun Formulas

テーブル変数を含んだ、列の計算式を、すべて再計算する。再計算は適切な順序で実行されます。

dt<<Reverse Order

データテーブル（dt）の列順を逆にする。

dt<<Revert

最後に保存されたデータテーブル（dt）に戻す。

dt<<Row Selection(Select Where(condition), <current selection("Extend"|"Restrict"|"Clear")> <Dialog("Keep Dialog Open")>)

説明

指定の条件を満たすすべての行を選択する。

必須の引数

Select Where(condition)

行を選択する条件。

オプションの引数

current selection("Extend"|"Restrict"|"Clear")

現在の選択範囲を拡張するか、制限するか、解除する。デフォルトではClear（解除）が使用されます。

Dialog("Keep Dialog Open")

ユーザがオプションを編集できるようにダイアログを表示する。

dt<<Run Formulas

他の計算式を評価した後で評価するために保留されている計算式も含め、データテーブルのすべての計算式の評価を実行する。

dt<<Run Script(name)

テーブルパネルにある、引用符付きのnameで指定されたプロパティのJSLスクリプトを実行する。

dt<<Save(path)

dt<<Save As(path)

説明

テーブルを、引用符付きのpathで指定されたパスに保存する。

次も参照

サポートされている形式については、『JMPの使用法』の作業データの保存と共有を参照してください。

dt<<Save Database(connection information, table name, <"Replace">)

データテーブルを、引用符付きの接続情報（connection information）と引用符付きのテーブル名（table name）で指定されたデータベースに保存する。"Replace"オプションを指定した場合は、既存のデータベースを置換します。

dt<<Save Script to Script Window

データテーブルを再作成するためのスクリプトをスクリプトエディタウィンドウに保存する。スクリプトウィンドウにスクリプトが入力されている場合は、その後ろにスクリプトを追加します。

dt<<Select All Rows

データテーブル（dt）のすべての行を選択する。

dt<<Select Columns(<column1>, <column2>,...|"All")

データテーブルの、指定された列（またはすべての列）を選択する。

dt<<Select Duplicate Rows

説明

値が重複している行のうち、2番目以降の行を選択する。列が選択または指定されている場合は、それらの列の値が重複した行を探します。重複しているかどうかの判断の際、大文字と小文字が区別されます。

次も参照

『スクリプトガイド』の重複した行の選択

dt<<Select Excluded

データテーブル（dt）で現在除外されている行だけを選択する。

dt<<Select Hidden

データテーブル（dt）で現在非表示になっている行だけを選択する。

dt<<Select Labeled

データテーブル（dt）で現在ラベルがついている行だけを選択する。

dt<<Select Randomly(n|p|Sample Size(n)|Sampling Rate(p))

指定された割合（p）、もしくは行数（n）でデータテーブルの行を無作為に選択する。引数をキーワードで指定する場合、0～1の数値は抽出率、1より大きい数値は行数を表します。

dt<<Select Rows([row1, row2, ...])

行番号のリスト（list）で指定された行を選択する。

dt<<Select Script Group(<group name|{group1, group2, ...}>)

引用符付きのグループ名（group name）または引用符付きの文字列のリストで 指定されたテーブルスクリプトのグループを選択する。引数がない場合は、すべてのグループを選択します。

dt<<Select Where(condition, <Current Selection("Extend"|"Restrict"|
"Clear")>)

説明

データテーブル（dt）で、条件（condition）が真になる行を選択する。

次も参照

『スクリプトガイド』の条件による選択

dt<<Set Dirty(Boolean)

変更されていない場合でも、データテーブルを変更済みとしてマークする。

dt <<Set Edit Lock(<"Modify Cells">, <"Add Rows">, <"Add Columns">, <"Delete Rows">, <"Delete Columns">)

説明

セルの変更や、行の追加・削除、列の追加・削除ができないようロックする。

次も参照

『スクリプトガイド』のデータテーブルの変更防止

dt <<Set Cell Height(n)

セルの高さをピクセル数で指定する。

dt<<Set Header Height(n)

セルの見出しの高さをピクセル数で指定する。

dt<<Set Label Columns(column1, columns2, ...)

指定の列をラベル列として割り当てる。

dt<<Set Matrix([matrix])

データテーブルに指定の行列を挿入し、必要に応じて新しい列と行を追加する。

dt<<Set Name(name)

説明

テーブルの名前を指定する。name引数は引用符付きです。

戻り値

データテーブル名の引用符付き文字列

メモ

Set Nameメッセージが、新しいテーブル名の引用符付き文字列を戻すように変更されました。以前のリリースでは、このメッセージは、スクリプト可能なデータテーブルオブジェクトを戻していました。この変更に伴い、JMPスクリプトを変更する必要がある場合があります。たとえば、以下のスクリプトは書き換える必要があります。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" ) << Set Name( "テスト" );

dtが「テスト」にならないように、メッセージを分けます。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << Set Name( "テスト" );

これは以前のリリースと同じ結果になり、JMPの以前のバージョンと新しいバージョンの両方に対応します。

dt<<Set Property(name, script)

dt<<New Script(name, script)を参照してください。

dt<<Set Label Columns(column(s), ...)

dt<<Set Label Columns

指定した列のラベルの属性をオン（ラベルあり）にする。列がリストされていない場合は、ラベルの属性がオフになります。

dt<<Set Row ID Width(n)

行番号が表示されている領域の表示幅を指定のピクセル数にする。nを0に設定すると、行番号の表示幅が自動的に調整されます。

dt<<Set Row States([matrix])

データテーブル内のすべての行の属性を設定する。

dt<<Set Scroll Lock Columns(column name, ...)

引用符付きの文字列で指定された列に対し、スクロールをロックする。列が指定されていないときは、スクロールのロックを解除します。

dt<<Set Table Variable(name, value)

dt<<New Table Variable(name, number)を参照してください。

dt<<Sort(<"Private">|<"Invisible">, <"Replace Table">, By(columns), Order("Descending" | "Ascending"), <Output Table Name(name))>

説明

列（columns）の値に従って、データテーブル（dt）の行を並べ替え、新しいデータテーブル（"name"）を作成する。

戻り値

並べ替えたテーブルへの参照

次も参照

『スクリプトガイド』のデータテーブルを並べ替えるを参照してください。

『JMPの使用法』のデータテーブルの並べ替えを参照してください。

dt<<Split(Split(columns), Split By(column), <Group(column)>, <"Private">|<"Invisible">, <Remaining Columns("Keep All"|"Drop All"| Keep(columns)|Drop(columns))>, <Copy Formula(Boolean)>, <Suppress Formula Evaluation(Boolean)>, <Sort by Column Property>, <Output Table (name)>)

説明

Splitで指定した各列をSplit byの列の値により複数の列に分割する。SplitとSplit byの引数は必須です。

戻り値

列の分割で作成されたデータテーブルへの参照

必須の引数

Split(columns)

分割する列。

Split By(column)

分割の基準となる列。

オプションの引数

Group

指定のグループ内でデータを分割する。

Remaining Columns("Keep All"|"Drop All"| Keep(columns)|Drop(columns))

残りの列を結果のテーブル内に含めるか指定する。デフォルトではKeep All（すべて保持）。

メモ: Keep Allは、出力データテーブルにすべての列を含めます。ただし、各列の値は含めません。出力データテーブルでは、複数の行が畳んで1つの行にまとめられるため、保持した列の値の一部が省略されます。

Copy Formula(Boolean)

ソーステーブルの列の計算式を結果のテーブルに含める。

Suppress Formula Evaluation(Boolean)

コピーされた列の計算式を自動評価しない。デフォルトは1（真）。

Sort by Column Property

出力列を、基準となる列（Split by）に対して定義された並べ替え列プロパティで並べ替える。

Output Table(name)

出力テーブルの名前を指定する。

次も参照

『スクリプトガイド』の積み重ねた後のデータテーブルで値を分割する

『JMPの使用法』の列の分割

dt<<Stack(<"Private">|<"Invisible">, Columns(columns), <Source Label Column(quoted string)>, <Stacked Data Column(quoted string)>, <Copy Formula(Boolean)>, <Suppress Formula Evaluation(Boolean)>, <Drop All Other Columns(Boolean)|Name(non-stacked columns)(Keep(column1, column2, ...))|Name(non-stacked columns) (Drop(column1, column2, ...))>, <Output Table(name)>), <Number of Series(n)>, <"Contiguous">

説明

データテーブル（dt）内の複数列の値を1列（newcol）に積み重ねて、新しいテーブルを作成する。

戻り値

列の積み重ねで作成されたデータテーブルへの参照

次も参照

『スクリプトガイド』のデータテーブル内の値を積み重ねる

『JMPの使用法』の列の積み重ね

dt<<Subscribe("keyname"(<"client">), On Delete Columns(<function>|
<script>)|On Add Columns(<function>|<script>)|On Add Rows(<function>|
<script>)|On Delete Rows(<function>|<script>)|On Rename Column(<function>|<script>)|On Close(<function>|<script>)|On Save(<function>|<script>)|On Rename(<function>|<script>))

説明

そのデータテーブルへの変更に関するメッセージを取得するため、データテーブルに登録する。

戻り値

キー名

引数

"keyname"(<client>)

登録を参照できるように登録名を指定する。データテーブルで閉じる操作が行われると、引用符付きのclientで指定されたクライアントが、そのデータテーブルに依存するウィンドウがあることを警告し、操作を実行するかどうかを確認します。

On Delete Columns(<function>|<script>)

列の削除時にキー名を戻す。

On Add Columns(<function>|<script>)

列の追加時にキー名を戻す。

On Add Rows(<function>|<script>)

行の追加時にキー名を戻す。

On Delete Rows(<function>|<script>)

行の削除時にキー名を戻す。

On Rename Column(<function>|<script>)

列名の変更時にキー名を戻す。

On Close(<function>|<script>)

データテーブルを閉じるときにキー名を戻す。1つの引数（関数）を取ります。その関数は、引数としてデータテーブル名のみを必要とします。

On Save(<function>|<script>)

データテーブルの保存時にキー名を戻す。

On Rename(<function>|<script>)

データテーブル名の変更が試みられると、キー名を戻す。関数（function）は、前に定義した関数か、その関数自体の名前です。

メモ

それぞれのオプションは、解除するまで有効です。

次も参照

『スクリプトガイド』のデータテーブルに登録（Subscribe）する

dt<<Subset(<"Private">|<"Invisible">, <"Selected Columns">, <Columns(column list)>, <"Selected Rows">, <Rows([number, number, ...])>, <By(column list)>, <Sampling Rate(fraction)>, <Sample Size(integer)>, <Stratify(column list)>, <Link to Original Data Table(Boolean)>, <Copy Formula(Boolean)>, <Suppress Formula Evaluation(Boolean)>, <"Keep by Columns">)

説明

データテーブル（dt）から指定された行と列を抽出し、新しいデータテーブルを作成する。

戻り値

サブセットデータテーブルへの参照

次も参照

『スクリプトガイド』のデータテーブルのサブセットを作成する

『JMPの使用法』のサブセットの作成

dt<<Summary(<"Private">|<"Invisible">, <Group(column)>, <Subgroup(column)>, <N(column)>, <Mean(column)>, <Std Dev(column)>, <Min(column)>, <Max(column)>, <Range(column)>, <Sum(column)>, <CV(column)>, <Freq(column)>, <Weight(column)>, "Include Marginal Statistics", <Link to Original Data Table(Boolean)>, <Statistics Column Name Format(Stat(column)|Column|Stat of Column|Column Stat)>)

説明

指定した列の要約統計量を含むデータテーブルを（オプションで、グループやサブグループごとに）作成する。Statistics Column Name Formatの値は引用符付きです。

戻り値

要約データテーブルへの参照

次も参照

『スクリプトガイド』のSummaryによる要約テーブルの作成

『JMPの使用法』のデータの要約

dt<<Suppress Formula Eval(Boolean)

引数が1の場合、データテーブル（dt）の計算式の自動評価をオフにする。引数が0の場合は、オンにする。

dt<<Text to Columns(Delimiters(<separator>, <"Tab">, <"Newline">), Columns(column1, column2...))

区切り文字で区切ったテキストから、テキストごとの列もしくは指示変数の列を作成する。"newline"には、\r、\n、\r\nの3つのいずれかを指定できます。区切り文字は引用符付きです。

例

dt = Open( "$SAMPLE_DATA/Consumer Preferences.jmp" );

dt << Text To Columns(

	delimiter( "," ),

	columns( :歯磨き カンマ区切り )

);

dt<<Transpose(Columns(columns), Rows([matrix]), Output Table Name(name))

説明

指定の行と列を転置し、（引用符付きのnameで指定された名前の）新しいデータテーブルを作成する。

戻り値

転置したデータテーブルへの参照

dt<<Ungroup Columns({column1, column2, ...})

リスト引数で定義された列のグループを解除する。

dt<<Ungroup Scripts(Name of Script Group|{script1, script2,...})

説明

指定したテーブルスクリプトまたはグループをグループから除外する。Name of Script Group引数は、引用符付きです。

次も参照

『スクリプトガイド』のスクリプトのグループ化解除

dt<<Unsubscribe(keyname, "On Delete Columns"|"On Add Columns"|"On Add Rows"|"On Delete Rows"|"On Close"|"On Col Rename"|"All")

データテーブル（dt）への以前の登録を解除する。keyname引数は引用符付きです。

dt<<Update from Database

データテーブル（dt）内のデータを、データベースから再読み込みしたデータで更新する。

より詳細な情報が必要な場合や、質問があるときは、JMPユーザーコミュニティで答えを見つけましょう (community.jmp.com).